Rules for integrands of the form(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)

0.  ∫(((f x))^m) (((e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

1.  ∫(((f x))^m) (((e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when m∈ℤ ∨ f>0

1:  ∫(((f x))^m) (((e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p) dx  when (m∈ℤ ∨ f>0) ∧ ((m+1)/n)∈ℤ

Derivation: Integration by substitution

Basis: If  ((m+1)/n)∈ℤ, then (x^m) (((e (x^n)))^q)==(1/(e^(((m+1)/n)-1))) (x^(n-1)) (((e (x^n)))^(q+((m+1)/n)-1))

Basis: (x^(n-1))F[(x^n)]==(1/n) Subst[F[x],x,(x^n)] (∂_x)(x^n)

Rule 1.2.3.4.0.1.1: If  (m∈ℤ ∨ f>0) ∧ ((m+1)/n)∈ℤ, then

∫(((f x))^m) (((e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p) dx  ⟶  ((f^m)/(n (e^(((m+1)/n)-1)))) Subst[∫(((e x))^(q+((m+1)/n)-1)) (((a+b x+c (x^2)))^p)dx,x,(x^n)]

Program code:

Int[(f_.*x_)^m_.*(e_.*x_^n_)^q_*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  f^m/(n*e^((m+1)/n-1))*Subst[Int[(e*x)^(q+(m+1)/n-1)*(a+b*x+c*x^2)^p,x],x,x^n] /;
FreeQ[{a,b,c,e,f,m,n,p,q},x] && EqQ[n2,2*n] && (IntegerQ[m] || GtQ[f,0]) && IntegerQ[Simplify[(m+1)/n]]

Int[(f_.*x_)^m_.*(e_.*x_^n_)^q_*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  f^m/(n*e^((m+1)/n-1))*Subst[Int[(e*x)^(q+(m+1)/n-1)*(a+c*x^2)^p,x],x,x^n] /;
FreeQ[{a,c,e,f,m,n,p,q},x] && EqQ[n2,2*n] && (IntegerQ[m] || GtQ[f,0]) && IntegerQ[Simplify[(m+1)/n]]

2:  ∫(((f x))^m) (((e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (m∈ℤ ∨ f>0) ∧ ((m+1)/n)∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((e (x^n)))^q)/(x^(n q)))==0

Rule 1.2.3.4.0.1.2: If  (m∈ℤ ∨ f>0) ∧ ((m+1)/n)∉ℤ, then

∫(((f x))^m) (((e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (((f^m) (e^(IntPart[q])) (((e (x^n)))^(FracPart[q])))/(x^(n FracPart[q])))∫(x^(m+n q)) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(f_.*x_)^m_.*(e_.*x_^n_)^q_*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  f^m*e^IntPart[q]*(e*x^n)^FracPart[q]/x^(n*FracPart[q])*Int[x^(m+n*q)*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,e,f,m,n,p,q},x] && EqQ[n2,2*n] && (IntegerQ[m] || GtQ[f,0]) && Not[IntegerQ[Simplify[(m+1)/n]]]

Int[(f_.*x_)^m_.*(e_.*x_^n_)^q_*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  f^m*e^IntPart[q]*(e*x^n)^FracPart[q]/x^(n*FracPart[q])*Int[x^(m+n*q)*(a+c*x^(2*n))^p,x] /;
FreeQ[{a,c,e,f,m,n,p,q},x] && EqQ[n2,2*n] && (IntegerQ[m] || GtQ[f,0]) && Not[IntegerQ[Simplify[(m+1)/n]]]

2:  ∫(((f x))^m) (((e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when m∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((f x))^m)/(x^m))==0

Rule 1.2.3.4.0.2: If  m∉ℤ, then

∫(((f x))^m) (((e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (((f^(IntPart[m]))(((f x))^(FracPart[m])))/(x^(FracPart[m])))∫(x^m) (((e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(f_*x_)^m_.*(e_.*x_^n_)^q_*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  f^IntPart[m]*(f*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(e*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,e,f,m,n,p,q},x] && EqQ[n2,2*n] && Not[IntegerQ[m]]

Int[(f_*x_)^m_.*(e_.*x_^n_)^q_*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  f^IntPart[m]*(f*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(e*x^n)^q*(a+c*x^(2*n))^p,x] /;
FreeQ[{a,c,e,f,m,n,p,q},x] && EqQ[n2,2*n] && Not[IntegerQ[m]]

1:  ∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  m-n+1==0

Derivation: Integration by substitution

Basis: (x^(n-1))F[(x^n)]==(1/n) Subst[F[x],x,(x^n)] (∂_x)(x^n)

Rule 1.2.3.4.1: If  m-n+1==0, then

∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (1/n)Subst[∫(((d+e x))^q) (((a+b x+c (x^2)))^p)dx,x,(x^n)]

Program code:

Int[x_^m_.*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  1/n*Subst[Int[(d+e*x)^q*(a+b*x+c*x^2)^p,x],x,x^n] /;
FreeQ[{a,b,c,d,e,m,n,p,q},x] && EqQ[n2,2*n] && EqQ[Simplify[m-n+1],0]

Int[x_^m_.*(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  1/n*Subst[Int[(d+e*x)^q*(a+c*x^2)^p,x],x,x^n] /;
FreeQ[{a,c,d,e,m,n,p,q},x] && EqQ[n2,2*n] && EqQ[Simplify[m-n+1],0]

2:  ∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (p|q)∈ℤ ∧ n<0

Derivation: Algebraic expansion

Basis: If  (p|q)∈ℤ, then (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)==(x^(n (2 p+q)))(((e+d (x^(-n))))^q) (((c+b (x^(-n))+a (x^(-2 n))))^p)

Rule 1.2.3.4.2: If  (p|q)∈ℤ ∧ n<0, then

∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ∫(x^(m+n (2 p+q)))(((e+d (x^(-n))))^q) (((c+b (x^(-n))+a (x^(-2 n))))^p)dx

Program code:

Int[x_^m_.*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  Int[x^(m+n*(2*p+q))*(e+d*x^(-n))^q*(c+b*x^(-n)+a*x^(-2*n))^p,x] /;
FreeQ[{a,b,c,d,e,m,n},x] && EqQ[n2,2*n] && IntegersQ[p,q] && NegQ[n]

Int[x_^m_.*(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  Int[x^(m+n*(2*p+q))*(e+d*x^(-n))^q*(c+a*x^(-2*n))^p,x] /;
FreeQ[{a,c,d,e,m,n},x] && EqQ[n2,2*n] && IntegersQ[p,q] && NegQ[n]

3.  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ

1:  ∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ ∧ (m|n|((m+1)/n))∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: If ((m+1)/n)∈ℤ, then (x^m)F[(x^n)]==(1/n) Subst[(x^(((m+1)/n)-1)) F[x],x,(x^n)] (∂_x)(x^n)

Note: If this substitution rule is applied when m∈(SuperMinus[ℤ]), expressions of the form Log[(x^n)] rather than Log[x] may appear in the antiderivative.

Rule 1.2.3.4.3.1: If  (b^2)-4 a c==0 ∧ p∉ℤ ∧ (m|n|((m+1)/n))∈(SuperPlus[ℤ]), then

∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (1/n) Subst[∫(x^(((m+1)/n)-1)) (((d+e x))^q) (((a+b x+c (x^2)))^p)dx,x,(x^n)]

Program code:

Int[x_^m_.*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  1/n*Subst[Int[x^((m+1)/n-1)*(d+e*x)^q*(a+b*x+c*x^2)^p,x],x,x^n] /;
FreeQ[{a,b,c,d,e,p,q},x] && EqQ[n2,2*n] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[p]] && IGtQ[m,0] && IGtQ[n,0] && IGtQ[(m+1)/n,0]

2:  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: If  (b^2)-4 a c==0, then (∂_x)((((a+b (x^n)+c (x^(2 n))))^p)/((((b/2)+c (x^n)))^(2 p)))==0

Basis: If  (b^2)-4 a c==0, then ((((a+b (x^n)+c (x^(2 n))))^p)/((((b/2)+c (x^n)))^(2 p)))==((((a+b (x^n)+c (x^(2 n))))^(FracPart[p]))/((c^(IntPart[p])) ((((b/2)+c (x^n)))^(2 FracPart[p]))))

Rule 1.2.3.4.3.2: If  (b^2)-4 a c==0 ∧ p∉ℤ, then

∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ((((a+b (x^n)+c (x^(2 n))))^(FracPart[p]))/((c^(IntPart[p])) ((((b/2)+c (x^n)))^(2 FracPart[p]))))∫(((f x))^m) (((d+e (x^n)))^q)((((b/2)+c (x^n)))^(2 p))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  (a+b*x^n+c*x^(2*n))^FracPart[p]/(c^IntPart[p]*(b/2+c*x^n)^(2*FracPart[p]))*
    Int[(f*x)^m*(d+e*x^n)^q*(b/2+c*x^n)^(2*p),x] /;
FreeQ[{a,b,c,d,e,f,m,n,p,q},x] && EqQ[n2,2*n] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[p]]

4.  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  ((m+1)/n)∈ℤ

1:  ∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when ((m+1)/n)∈ℤ

Derivation: Integration by substitution

Basis: If ((m+1)/n)∈ℤ, then (x^m)F[(x^n)]==(1/n) Subst[(x^(((m+1)/n)-1)) F[x],x,(x^n)] (∂_x)(x^n)

Note: If  n∈ℤ ∧ ((m+1)/n)∈ℤ, then m∈ℤ, and (((f x))^m) automatically evaluates to (f^m)(x^m).

Rule 1.2.3.4.4.1: If ((m+1)/n)∈ℤ, then

∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (1/n) Subst[∫(x^(((m+1)/n)-1)) (((d+e x))^q) (((a+b x+c (x^2)))^p)dx,x,(x^n)]

Program code:

Int[x_^m_.*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  1/n*Subst[Int[x^(Simplify[(m+1)/n]-1)*(d+e*x)^q*(a+b*x+c*x^2)^p,x],x,x^n] /;
FreeQ[{a,b,c,d,e,m,n,p,q},x] && EqQ[n2,2*n] && IntegerQ[Simplify[(m+1)/n]]

Int[x_^m_.*(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  1/n*Subst[Int[x^(Simplify[(m+1)/n]-1)*(d+e*x)^q*(a+c*x^2)^p,x],x,x^n] /;
FreeQ[{a,c,d,e,m,n,p,q},x] && EqQ[n2,2*n] && IntegerQ[Simplify[(m+1)/n]]

2:  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  ((m+1)/n)∈ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((f x))^m)/(x^m))==0

Basis: ((((f x))^m)/(x^m))==(((f^(IntPart[m]))(((f x))^(FracPart[m])))/(x^(FracPart[m])))

Rule 1.2.3.4.4.2: If ((m+1)/n)∈ℤ, then

∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (((f^(IntPart[m]))(((f x))^(FracPart[m])))/(x^(FracPart[m])))∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(f_*x_)^m_.*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  f^IntPart[m]*(f*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(d+e*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,f,m,n,p,q},x] && EqQ[n2,2*n] && IntegerQ[Simplify[(m+1)/n]]

Int[(f_*x_)^m_.*(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  f^IntPart[m]*(f*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(d+e*x^n)^q*(a+c*x^(2*n))^p,x] /;
FreeQ[{a,c,d,e,f,m,n,p,q},x] && EqQ[n2,2*n] && IntegerQ[Simplify[(m+1)/n]]

5.  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2n))))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0

1:  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2n))))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: If  c (d^2)-b d e+a (e^2)==0, then a+b z+c (z^2)==(d+e z) ((a/d)+((c z)/e))

Rule 1.2.3.4.5.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∈ℤ, then

∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2n))))^p)dx  ⟶  ∫(((f x))^m)(((d+e (x^n)))^(q+p)) ((((a/d)+((c (x^n))/e)))^p)dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_)^p_.,x_Symbol] :=
  Int[(f*x)^m*(d+e*x^n)^(q+p)*(a/d+c/e*x^n)^p,x] /;
FreeQ[{a,b,c,d,e,f,m,n,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && IntegerQ[p]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_)^p_.,x_Symbol] :=
  Int[(f*x)^m*(d+e*x^n)^(q+p)*(a/d+c/e*x^n)^p,x] /;
FreeQ[{a,c,d,e,f,q,m,n,q},x] && EqQ[n2,2*n] && EqQ[c*d^2+a*e^2,0] && IntegerQ[p]

2:  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2n))))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: If  c (d^2)-b d e+a (e^2)==0, then (∂_x)((((a+b (x^n)+c (x^(2 n))))^p)/((((d+e (x^n)))^p) ((((a/d)+((c (x^n))/e)))^p)))==0

Basis: If  c (d^2)-b d e+a (e^2)==0, then ((((a+b (x^n)+c (x^(2 n))))^p)/((((d+e (x^n)))^p) ((((a/d)+((c (x^n))/e)))^p)))==((((a+b (x^n)+c (x^(2 n))))^(FracPart[p]))/((((d+e (x^n)))^(FracPart[p])) ((((a/d)+((c (x^n))/e)))^(FracPart[p]))))

Rule 1.2.3.4.5.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ, then

∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2n))))^p)dx  ⟶  ((((a+b (x^n)+c (x^(2 n))))^(FracPart[p]))/((((d+e (x^n)))^(FracPart[p])) ((((a/d)+((c (x^n))/e)))^(FracPart[p]))))∫(((f x))^m)(((d+e (x^n)))^(q+p)) ((((a/d)+((c (x^n))/e)))^p)dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_*(a_+b_.*x_^n_+c_.*x_^n2_)^p_,x_Symbol] :=
  (a+b*x^n+c*x^(2*n))^FracPart[p]/((d+e*x^n)^FracPart[p]*(a/d+(c*x^n)/e)^FracPart[p])*
    Int[(f*x)^m*(d+e*x^n)^(q+p)*(a/d+c/e*x^n)^p,x] /;
FreeQ[{a,b,c,d,e,f,m,n,p,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_*(a_+c_.*x_^n2_)^p_,x_Symbol] :=
  (a+c*x^(2*n))^FracPart[p]/((d+e*x^n)^FracPart[p]*(a/d+(c*x^n)/e)^FracPart[p])*Int[(f*x)^m*(d+e*x^n)^(q+p)*(a/d+c/e*x^n)^p,x] /;
FreeQ[{a,c,d,e,f,m,n,p,q},x] && EqQ[n2,2*n] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]]

6.  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈ℤ

1.  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])

1.  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ (n|p)∈(SuperPlus[ℤ])

1.  ∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ (n|p)∈(SuperPlus[ℤ])∧ (m|q)∈ℤ ∧ q<-1

1:  ∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ (n|p)∈(SuperPlus[ℤ])∧ (m|q)∈ℤ ∧ q<-1 ∧ m>0

Derivation: Algebraic expansion and binomial recurrence 2b

Note: If  (n|p)∈(SuperPlus[ℤ])∧ (m|q)∈ℤ ∧ q<0, then ((((-d))^((m-Mod[m,n])/n))/(e^(2 p+(m-Mod[m,n])/n))) (∑_(k=0)^(2 p))(((-d))^k) (e^(2 p-k)) (Subscript[P, 2 p])[(x^n),k] is the coefficient of the (x^(Mod[m,n])) (((d+e (x^n)))^q) term of the partial fraction expansion of (x^m) (Subscript[P, 2 p])[(x^n)] (((d+e (x^n)))^q).

Note: If  (n|p)∈(SuperPlus[ℤ])∧ (m|q)∈ℤ ∧ q<-1 ∧ m>0, then n (e^(2 p+(m-Mod[m,n])/n)) (q+1)(x^(m-Mod[m,n]))(((a+b (x^n)+c (x^(2 n))))^p)-(((-d))^((m-Mod[m,n])/n-1)) (((c (d^2)-b d e+a (e^2)))^p) (d (Mod[m,n]+1)+e (Mod[m,n]+n (q+1)+1) (x^n)) will be divisible by a+b (x^n).

Note: In the resulting integrand the degree of the polynomial in (x^n) is at most q-1 .

Rule 1.2.3.4.6.1.1.1.1: If  (b^2)-4 a c≠0 ∧ (n|p)∈(SuperPlus[ℤ])∧ (m|q)∈ℤ ∧ q<-1 ∧ m>0, then

∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  

((((-d))^((m-Mod[m,n])/n))/(e^(2 p+(m-Mod[m,n])/n))) (((c (d^2)-b d e+a (e^2)))^p) ∫(x^(Mod[m,n])) (((d+e (x^n)))^q)dx+
(1/(e^(2 p+(m-Mod[m,n])/n))) ∫(x^(Mod[m,n])) (((d+e (x^n)))^q) ((e^(2 p+(m-Mod[m,n])/n)) (x^(m-Mod[m,n]))(((a+b (x^n)+c (x^(2 n))))^p)-(((-d))^((m-Mod[m,n])/n)) (((c (d^2)-b d e+a (e^2)))^p))dx  ⟶  

(((((-d))^((m-Mod[m,n])/n-1)) (((c (d^2)-b d e+a (e^2)))^p) (x^(Mod[m,n]+1)) (((d+e (x^n)))^(q+1)))/(n (e^(2 p+(m-Mod[m,n])/n)) (q+1)))+
(1/(n (e^(2 p+(m-Mod[m,n])/n)) (q+1)))∫(x^(Mod[m,n])) (((d+e (x^n)))^(q+1))·
(((n (e^(2 p+(m-Mod[m,n])/n)) (q+1)(x^(m-Mod[m,n]))(((a+b (x^n)+c (x^(2 n))))^p)-(((-d))^((m-Mod[m,n])/n-1)) (((c (d^2)-b d e+a (e^2)))^p) (d (Mod[m,n]+1)+e (Mod[m,n]+n (q+1)+1) (x^n)))/(d+e (x^n))) )dx

Program code:

Int[x_^m_.*(d_+e_.*x_^n_)^q_*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  (-d)^((m-Mod[m,n])/n-1)*(c*d^2-b*d*e+a*e^2)^p*x^(Mod[m,n]+1)*(d+e*x^n)^(q+1)/(n*e^(2*p+(m-Mod[m,n])/n)*(q+1)) + 
  1/(n*e^(2*p+(m-Mod[m,n])/n)*(q+1))*Int[x^Mod[m,n]*(d+e*x^n)^(q+1)*
    ExpandToSum[Together[1/(d+e*x^n)*(n*e^(2*p+(m-Mod[m,n])/n)*(q+1)*x^(m-Mod[m,n])*(a+b*x^n+c*x^(2*n))^p-
      (-d)^((m-Mod[m,n])/n-1)*(c*d^2-b*d*e+a*e^2)^p*(d*(Mod[m,n]+1)+e*(Mod[m,n]+n*(q+1)+1)*x^n))],x],x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && IGtQ[p,0] && ILtQ[q,-1] && IGtQ[m,0]

Int[x_^m_.*(d_+e_.*x_^n_)^q_*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  (-d)^((m-Mod[m,n])/n-1)*(c*d^2+a*e^2)^p*x^(Mod[m,n]+1)*(d+e*x^n)^(q+1)/(n*e^(2*p+(m-Mod[m,n])/n)*(q+1)) + 
  1/(n*e^(2*p+(m-Mod[m,n])/n)*(q+1))*Int[x^Mod[m,n]*(d+e*x^n)^(q+1)*
    ExpandToSum[Together[1/(d+e*x^n)*(n*e^(2*p+(m-Mod[m,n])/n)*(q+1)*x^(m-Mod[m,n])*(a+c*x^(2*n))^p-
      (-d)^((m-Mod[m,n])/n-1)*(c*d^2+a*e^2)^p*(d*(Mod[m,n]+1)+e*(Mod[m,n]+n*(q+1)+1)*x^n))],x],x] /;
FreeQ[{a,c,d,e},x] && EqQ[n2,2*n] && IGtQ[n,0] && IGtQ[p,0] && ILtQ[q,-1] && IGtQ[m,0]

2:  ∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ (n|p)∈(SuperPlus[ℤ])∧ (m|q)∈ℤ ∧ q<-1 ∧ m<0

Derivation: Algebraic expansion and binomial recurrence 2b

Note: If  (n|p)∈(SuperPlus[ℤ])∧ (m|q)∈ℤ ∧ q<0, then ((((-d))^((m-Mod[m,n])/n))/(e^(2 p+(m-Mod[m,n])/n))) (∑_(k=0)^(2 p))(((-d))^k) (e^(2 p-k)) (Subscript[P, 2 p])[(x^n),k] is the coefficient of the (x^(Mod[m,n])) (((d+e (x^n)))^q) term of the partial fraction expansion of (x^m) (Subscript[P, 2 p])[(x^n)] (((d+e (x^n)))^q).

Note: If  (n|p)∈(SuperPlus[ℤ])∧ (m|q)∈ℤ ∧ q<-1 ∧ m<0, then n (((-d))^(-(m-Mod[m,n])/n+1)) (e^(2 p))(q+1) (((a+b (x^n)+c (x^(2 n))))^p)-(e^(-(m-Mod[m,n])/n)) (((c (d^2)-b d e+a (e^2)))^p) (x^(-(m-Mod[m,n]))) (d (Mod[m,n]+1)+e (Mod[m,n]+n (q+1)+1) (x^n)) will be divisible by a+b (x^n).

Note: In the resulting integrand the degree of the polynomial in (x^n) is at most q-1 .

Rule 1.2.3.4.6.1.1.1.2: If  (b^2)-4 a c≠0 ∧ (n|p)∈(SuperPlus[ℤ])∧ (m|q)∈ℤ ∧ q<-1 ∧ m<0, then

∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  

((((-d))^((m-Mod[m,n])/n))/(e^(2 p+(m-Mod[m,n])/n))) (((c (d^2)-b d e+a (e^2)))^p) ∫(x^(Mod[m,n])) (((d+e (x^n)))^q)dx+
((((-d))^((m-Mod[m,n])/n))/(e^(2 p))) ∫(x^m)(((d+e (x^n)))^q) ((((-d))^(-(m-Mod[m,n])/n)) (e^(2 p)) (((a+b (x^n)+c (x^(2 n))))^p)-(e^(-(m-Mod[m,n])/n)) (((c (d^2)-b d e+a (e^2)))^p) (x^(-m)))dx  ⟶  

(((((-d))^((m-Mod[m,n])/n-1)) (((c (d^2)-b d e+a (e^2)))^p) (x^(Mod[m,n]+1)) (((d+e (x^n)))^(q+1)))/(n (e^(2 p+(m-Mod[m,n])/n)) (q+1)))+
((((-d))^((m-Mod[m,n])/n-1))/(n (e^(2 p)) (q+1)))∫(x^m) (((d+e (x^n)))^(q+1))·
(((n (((-d))^(-(m-Mod[m,n])/n+1)) (e^(2 p))(q+1) (((a+b (x^n)+c (x^(2 n))))^p)-(e^(-(m-Mod[m,n])/n)) (((c (d^2)-b d e+a (e^2)))^p) (x^(-(m-Mod[m,n]))) (d (Mod[m,n]+1)+e (Mod[m,n]+n (q+1)+1) (x^n)))/(d+e (x^n))))dx

Program code:

Int[x_^m_*(d_+e_.*x_^n_)^q_*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  (-d)^((m-Mod[m,n])/n-1)*(c*d^2-b*d*e+a*e^2)^p*x^(Mod[m,n]+1)*(d+e*x^n)^(q+1)/(n*e^(2*p+(m-Mod[m,n])/n)*(q+1)) + 
  (-d)^((m-Mod[m,n])/n-1)/(n*e^(2*p)*(q+1))*Int[x^m*(d+e*x^n)^(q+1)*
    ExpandToSum[Together[1/(d+e*x^n)*(n*(-d)^(-(m-Mod[m,n])/n+1)*e^(2*p)*(q+1)*(a+b*x^n+c*x^(2*n))^p - 
  (e^(-(m-Mod[m,n])/n)*(c*d^2-b*d*e+a*e^2)^p*x^(-(m-Mod[m,n])))*(d*(Mod[m,n]+1)+e*(Mod[m,n]+n*(q+1)+1)*x^n))],x],x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && IGtQ[p,0] && ILtQ[q,-1] && ILtQ[m,0]

Int[x_^m_*(d_+e_.*x_^n_)^q_*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  (-d)^((m-Mod[m,n])/n-1)*(c*d^2+a*e^2)^p*x^(Mod[m,n]+1)*(d+e*x^n)^(q+1)/(n*e^(2*p+(m-Mod[m,n])/n)*(q+1)) + 
  (-d)^((m-Mod[m,n])/n-1)/(n*e^(2*p)*(q+1))*Int[x^m*(d+e*x^n)^(q+1)*
    ExpandToSum[Together[1/(d+e*x^n)*(n*(-d)^(-(m-Mod[m,n])/n+1)*e^(2*p)*(q+1)*(a+c*x^(2*n))^p - 
  (e^(-(m-Mod[m,n])/n)*(c*d^2+a*e^2)^p*x^(-(m-Mod[m,n])))*(d*(Mod[m,n]+1)+e*(Mod[m,n]+n*(q+1)+1)*x^n))],x],x] /;
FreeQ[{a,c,d,e},x] && EqQ[n2,2*n] && IGtQ[n,0] && IGtQ[p,0] && IntegersQ[m,q] && ILtQ[q,-1] && ILtQ[m,0]

2:  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ (n|p)∈(SuperPlus[ℤ])∧ 2 n p>n-1 ∧ q∉ℤ ∧ m+2 n p+n q+1≠0

Reference: G&R 2.104

Note: This rule is a special case of the Ostrogradskiy-Hermite integration method.

Note: The degree of the polynomial in the resulting integrand is less than 2 n.

Rule 1.2.3.4.6.1.1.2: If  (b^2)-4 a c≠0 ∧ (n|p)∈(SuperPlus[ℤ])∧ 2 n p>n-1 ∧ q∉ℤ ∧ m+2 n p+n q+1≠0, then

∫(((f x))^m)  (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  

∫(((f x))^m)  (((d+e (x^n)))^q) ((((a+b (x^n)+c (x^(2 n))))^p)- (x^(2 n p)))dx+((c^p)/(f^(2 n p)))∫(((f x))^(m+2 n p))(((d+e (x^n)))^q)dx  ⟶  

(((c^p) (((f x))^(m+2 n p-n+1)) (((d+e (x^n)))^(q+1)))/(e (f^(2 n p-n+1)) (m+2 n p+n q+1)))+
(1/(e (m+2 n p+n q+1)))∫(((f x))^m) (((d+e (x^n)))^q) (e (m+2 n p+n q+1) ((((a+b (x^n)+c (x^(2 n))))^p)-(c^p) (x^(2 n p)))-d (c^p) (m+2 n p-n+1)(x^(2 n p-n)))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  c^p*(f*x)^(m+2*n*p-n+1)*(d+e*x^n)^(q+1)/(e*f^(2*n*p-n+1)*(m+2*n*p+n*q+1)) + 
  1/(e*(m+2*n*p+n*q+1))*Int[(f*x)^m*(d+e*x^n)^q*
    ExpandToSum[e*(m+2*n*p+n*q+1)*((a+b*x^n+c*x^(2*n))^p-c^p*x^(2*n*p))-d*c^p*(m+2*n*p-n+1)*x^(2*n*p-n),x],x] /;
FreeQ[{a,b,c,d,e,f,m,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && IGtQ[p,0] && GtQ[2*n*p,n-1] && 
  Not[IntegerQ[q]] && NeQ[m+2*n*p+n*q+1,0]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  c^p*(f*x)^(m+2*n*p-n+1)*(d+e*x^n)^(q+1)/(e*f^(2*n*p-n+1)*(m+2*n*p+n*q+1)) + 
  1/(e*(m+2*n*p+n*q+1))*Int[(f*x)^m*(d+e*x^n)^q*
    ExpandToSum[e*(m+2*n*p+n*q+1)*((a+c*x^(2*n))^p-c^p*x^(2*n*p))-d*c^p*(m+2*n*p-n+1)*x^(2*n*p-n),x],x] /;
FreeQ[{a,c,d,e,f,m,q},x] && EqQ[n2,2*n] && IGtQ[n,0] && IGtQ[p,0] && GtQ[2*n*p,n-1] && 
  Not[IntegerQ[q]] && NeQ[m+2*n*p+n*q+1,0]

3:  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ (n|p)∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule 1.2.3.4.6.1.1.3: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ]), then

∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ∫ExpandIntegrand[(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m(d+e*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x],x] /;
FreeQ[{a,b,c,d,e,f,m,q},x] && EqQ[n2,2*n] && IGtQ[n,0] && IGtQ[p,0]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m(d+e*x^n)^q*(a+c*x^(2*n))^p,x],x] /;
FreeQ[{a,c,d,e,f,m,q},x] && EqQ[n2,2*n] && IGtQ[n,0] && IGtQ[p,0]

2:  ∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m∈ℤ ∧ GCD[m+1,n]≠1

Derivation: Integration by substitution

Basis: If  n∈ℤ ∧ m∈ℤ, let k=GCD[m+1,n], then (x^m) F[(x^n)]==(1/k)Subst[(x^(((m+1)/k)-1)) F[(x^(n/k))],x,(x^k)] (∂_x)(x^k)

Rule 1.2.3.4.6.1.2: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m∈ℤ, let k=GCD[m+1,n], if  k≠1, then

∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (1/k) Subst[∫(x^(((m+1)/k)-1)) (((d+e (x^(n/k))))^q) (((a+b (x^(n/k))+c (x^(2 n/k))))^p)dx,x,(x^k)]

Program code:

Int[x_^m_.*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  With[{k=GCD[m+1,n]},
  1/k*Subst[Int[x^((m+1)/k-1)*(d+e*x^(n/k))^q*(a+b*x^(n/k)+c*x^(2*n/k))^p,x],x,x^k] /;
 k≠1] /;
FreeQ[{a,b,c,d,e,p,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && IntegerQ[m]

Int[x_^m_.*(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_.)^p_,x_Symbol] :=
  With[{k=GCD[m+1,n]},
  1/k*Subst[Int[x^((m+1)/k-1)*(d+e*x^(n/k))^q*(a+c*x^(2*n/k))^p,x],x,x^k] /;
 k≠1] /;
FreeQ[{a,c,d,e,p,q},x] && EqQ[n2,2*n] && IGtQ[n,0] && IntegerQ[m]

3:  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m∈𝔽

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then (((f x))^m) F[x]==(k/f) Subst[(x^(k (m+1)-1))F[((x^k)/f)],x,(((f x))^(1/k))] (∂_x)(((f x))^(1/k))

Rule 1.2.3.4.6.1.3: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m∈𝔽, let k=Denominator[m], then

∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (k/f) Subst[∫(x^(k (m+1)-1)) (((d+((e (x^(k n)))/(f^n))))^q) (((a+((b (x^(k n)))/(f^n))+((c (x^(2 k n)))/(f^(2 n)))))^p) dx,x,(((f x))^(1/k))]

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  With[{k=Denominator[m]},
  k/f*Subst[Int[x^(k*(m+1)-1)*(d+e*x^(k*n)/f^n)^q*(a+b*x^(k*n)/f^n+c*x^(2*k*n)/f^(2*n))^p,x],x,(f*x)^(1/k)]] /;
FreeQ[{a,b,c,d,e,f,p,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && FractionQ[m] && IntegerQ[p]

Int[(f_.*x_)^m_*(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_.)^p_,x_Symbol] :=
  With[{k=Denominator[m]},
  k/f*Subst[Int[x^(k*(m+1)-1)*(d+e*x^(k*n)/f)^q*(a+c*x^(2*k*n)/f)^p,x],x,(f*x)^(1/k)]] /;
FreeQ[{a,c,d,e,f,p,q},x] && EqQ[n2,2*n] && IGtQ[n,0] && FractionQ[m] && IntegerQ[p]

4.  ∫(((f x))^m) (d+e (x^n))(((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])

1.  ∫(((f x))^m) (d+e (x^n))(((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p>0

1:  ∫(((f x))^m)(d+e (x^n))(((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p>0 ∧ m<-1 ∧ m+n(2 p+1)+1≠0

Derivation: Trinomial recurrence 1a

Rule 1.2.3.4.6.1.4.1.1: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p>0 ∧ m<-1 ∧ m+n(2 p+1)+1≠0, then

∫(((f x))^m) (d+e (x^n))(((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  
(((((f x))^(m+1)) (((a+b (x^n)+c (x^(2 n))))^p) (d (2 n p+n+m+1)+e (m+1) (x^n)))/(f (m+1) (m+n(2 p+1)+1)))+
((n p)/((f^n) (m+1) (m+n(2 p+1)+1)))∫(((f x))^(m+n)) (((a+b (x^n)+c (x^(2 n))))^(p-1))·
(2 a e (m+1)-b d (m+n(2 p+1)+1)+(b e (m+1)-2 c d (m+n(2 p+1)+1)) (x^n))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)*(a_+b_.*x_^n_+c_.*x_^n2_)^p_.,x_Symbol] :=
  (f*x)^(m+1)*(a+b*x^n+c*x^(2*n))^p*(d*(m+n*(2*p+1)+1)+e*(m+1)*x^n)/(f*(m+1)*(m+n*(2*p+1)+1)) + 
  n*p/(f^n*(m+1)*(m+n*(2*p+1)+1))*Int[(f*x)^(m+n)*(a+b*x^n+c*x^(2*n))^(p-1)*
      Simp[2*a*e*(m+1)-b*d*(m+n*(2*p+1)+1)+(b*e*(m+1)-2*c*d*(m+n*(2*p+1)+1))*x^n,x],x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && GtQ[p,0] && LtQ[m,-1] && NeQ[m+n*(2*p+1)+1,0] && IntegerQ[p]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)*(a_+c_.*x_^n2_)^p_.,x_Symbol] :=
  (f*x)^(m+1)*(a+c*x^(2*n))^p*(d*(m+n*(2*p+1)+1)+e*(m+1)*x^n)/(f*(m+1)*(m+n*(2*p+1)+1)) + 
  2*n*p/(f^n*(m+1)*(m+n*(2*p+1)+1))*Int[(f*x)^(m+n)*(a+c*x^(2*n))^(p-1)*(a*e*(m+1)-c*d*(m+n*(2*p+1)+1)*x^n),x] /;
FreeQ[{a,c,d,e,f},x] && EqQ[n2,2*n] && IGtQ[n,0] && GtQ[p,0] && LtQ[m,-1] && NeQ[m+n*(2*p+1)+1,0] && IntegerQ[p]

2:  ∫(((f x))^m)(d+e (x^n))(((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p>0 ∧ m+2 n p+1≠0 ∧ m+n(2 p+1)+1≠0

Derivation: Trinomial recurrence 1b

Rule 1.2.3.4.6.1.4.1.2: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p>0 ∧ m+2 n p+1≠0 ∧ m+n(2 p+1)+1≠0, then

∫(((f x))^m) (d+e (x^n))(((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  
(((((f x))^(m+1)) (((a+b (x^n)+c (x^(2 n))))^p) (b e n p+c d (m+2 n p+n+1)+c e(2 n p+m+1) (x^n)))/(c f (m+2 n p+1) (m+n(2 p+1)+1)))+
((n p)/(c (m+2 n p+1) (m+n(2 p+1)+1)))∫(((f x))^m) (((a+b (x^n)+c (x^(2 n))))^(p-1))·
(2 a c d(m+n(2 p+1)+1)-a b e (m+1)+(2 a c e(m+2 n p+1)+b c d (m+n(2 p+1)+1)-(b^2) e (m+n p+1)) (x^n))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)*(a_+b_.*x_^n_+c_.*x_^n2_)^p_.,x_Symbol] :=
  (f*x)^(m+1)*(a+b*x^n+c*x^(2*n))^p*(b*e*n*p+c*d*(m+n*(2*p+1)+1)+c*e*(2*n*p+m+1)*x^n)/
    (c*f*(2*n*p+m+1)*(m+n*(2*p+1)+1)) + 
  n*p/(c*(2*n*p+m+1)*(m+n*(2*p+1)+1))*Int[(f*x)^m*(a+b*x^n+c*x^(2*n))^(p-1)*
    Simp[2*a*c*d*(m+n*(2*p+1)+1)-a*b*e*(m+1)+(2*a*c*e*(2*n*p+m+1)+b*c*d*(m+n*(2*p+1)+1)-b^2*e*(m+n*p+1))*x^n,x],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && GtQ[p,0] && NeQ[2*n*p+m+1,0] && NeQ[m+n*(2*p+1)+1,0] && IntegerQ[p]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)*(a_+c_.*x_^n2_)^p_.,x_Symbol] :=
  (f*x)^(m+1)*(a+c*x^(2*n))^p*(c*d*(m+n*(2*p+1)+1)+c*e*(2*n*p+m+1)*x^n)/(c*f*(2*n*p+m+1)*(m+n*(2*p+1)+1)) + 
  2*a*n*p/((2*n*p+m+1)*(m+n*(2*p+1)+1))*Int[(f*x)^m*(a+c*x^(2*n))^(p-1)*Simp[d*(m+n*(2*p+1)+1)+e*(2*n*p+m+1)*x^n,x],x] /;
FreeQ[{a,c,d,e,f,m},x] && EqQ[n2,2*n] && IGtQ[n,0] && GtQ[p,0] && NeQ[2*n*p+m+1,0] && NeQ[m+n*(2*p+1)+1,0] && IntegerQ[p]

2.  ∫(((f x))^m) (d+e (x^n))(((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1

1:  ∫(((f x))^m)(d+e (x^n))(((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ m>n-1

Derivation: Trinomial recurrence 2a

Rule 1.2.3.4.6.1.4.2.1: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ m>n-1, then

∫(((f x))^m) (d+e (x^n))(((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  
(( (f^(n-1)) (((f x))^(m-n+1)) (((a+b (x^n)+c (x^(2 n))))^(p+1)) (b d-2 a e-(b e-2 c d) (x^n)))/(n(p+1) ((b^2)-4 a c)))+
((f^n)/(n(p+1) ((b^2)-4 a c) ))∫(((f x))^(m-n)) (((a+b (x^n)+c (x^(2 n))))^(p+1)) ((n-m-1)(b d-2 a e)+(2n p+2n+m+1) (b e-2 c d) (x^n))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)*(a_+b_.*x_^n_+c_.*x_^n2_)^p_.,x_Symbol] :=
  f^(n-1)*(f*x)^(m-n+1)*(a+b*x^n+c*x^(2*n))^(p+1)*(b*d-2*a*e-(b*e-2*c*d)*x^n)/(n*(p+1)*(b^2-4*a*c)) + 
  f^n/(n*(p+1)*(b^2-4*a*c))*Int[(f*x)^(m-n)*(a+b*x^n+c*x^(2*n))^(p+1)*
      Simp[(n-m-1)*(b*d-2*a*e)+(2*n*p+2*n+m+1)*(b*e-2*c*d)*x^n,x],x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && LtQ[p,-1] && GtQ[m,n-1] && IntegerQ[p]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)*(a_+c_.*x_^n2_)^p_.,x_Symbol] :=
  f^(n-1)*(f*x)^(m-n+1)*(a+c*x^(2*n))^(p+1)*(a*e-c*d*x^n)/(2*a*c*n*(p+1)) + 
  f^n/(2*a*c*n*(p+1))*Int[(f*x)^(m-n)*(a+c*x^(2*n))^(p+1)*(a*e*(n-m-1)+c*d*(2*n*p+2*n+m+1)*x^n),x] /;
FreeQ[{a,c,d,e,f},x] && EqQ[n2,2*n] && IGtQ[n,0] && LtQ[p,-1] && GtQ[m,n-1] && IntegerQ[p]

2:  ∫(((f x))^m)(d+e (x^n))(((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1

Derivation: Trinomial recurrence 2b

Rule 1.2.3.4.6.1.4.2.2: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1, then

∫(((f x))^m) (d+e (x^n))(((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  
-(((((f x))^(m+1)) (((a+b (x^n)+c (x^(2 n))))^(p+1)) (d((b^2)-2 a c)-a b e+(b d-2 a e) c (x^n)))/(a f n(p+1) ((b^2)-4 a c)))+
(1/(a n(p+1)((b^2)-4 a c) ))∫(((f x))^m) (((a+b (x^n)+c (x^(2 n))))^(p+1))·
(d ((b^2) (m+n(p+1)+1)-2 a c (m+2n(p+1)+1))-a b e (m+1)+c (m+n(2p+3)+1)(b d-2 a e) (x^n))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)*(a_+b_.*x_^n_+c_.*x_^n2_)^p_,x_Symbol] :=
  -(f*x)^(m+1)*(a+b*x^n+c*x^(2*n))^(p+1)*(d*(b^2-2*a*c)-a*b*e+(b*d-2*a*e)*c*x^n)/(a*f*n*(p+1)*(b^2-4*a*c)) + 
  1/(a*n*(p+1)*(b^2-4*a*c))*Int[(f*x)^m*(a+b*x^n+c*x^(2*n))^(p+1)*
      Simp[d*(b^2*(m+n*(p+1)+1)-2*a*c*(m+2*n*(p+1)+1))-a*b*e*(m+1)+c*(m+n*(2*p+3)+1)*(b*d-2*a*e)*x^n,x],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && LtQ[p,-1] && IntegerQ[p]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)*(a_+c_.*x_^n2_)^p_,x_Symbol] :=
  -(f*x)^(m+1)*(a+c*x^(2*n))^(p+1)*(d+e*x^n)/(2*a*f*n*(p+1)) + 
  1/(2*a*n*(p+1))*Int[(f*x)^m*(a+c*x^(2*n))^(p+1)*Simp[d*(m+2*n*(p+1)+1)+e*(m+n*(2*p+3)+1)*x^n,x],x] /;
FreeQ[{a,c,d,e,f,m},x] && EqQ[n2,2*n] && IGtQ[n,0] && LtQ[p,-1] && IntegerQ[p]

3:  ∫(((f x))^m)(d+e (x^n))(((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m>n-1 ∧ m+n(2 p+1)+1≠0

Derivation: Trinomial recurrence 3a

Rule 1.2.3.4.6.1.4.3: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m>n-1 ∧ m+n(2 p+1)+1≠0, then

∫(((f x))^m) (d+e (x^n))(((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  
((e (f^(n-1)) (((f x))^(m-n+1))(((a+b (x^n)+c (x^(2 n))))^(p+1)))/(c (m+n(2 p+1)+1)))-
((f^n)/(c (m+n(2 p+1)+1)))∫(((f x))^(m-n)) (((a+b (x^n)+c (x^(2 n))))^p) (a e (m-n+1)+(b e (m+n p+1)-c d (m+n(2 p+1)+1)) (x^n))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)*(a_+b_.*x_^n_+c_.*x_^n2_)^p_,x_Symbol] :=
  e*f^(n-1)*(f*x)^(m-n+1)*(a+b*x^n+c*x^(2*n))^(p+1)/(c*(m+n(2*p+1)+1)) - 
  f^n/(c*(m+n(2*p+1)+1))*
    Int[(f*x)^(m-n)*(a+b*x^n+c*x^(2*n))^p*Simp[a*e*(m-n+1)+(b*e*(m+n*p+1)-c*d*(m+n(2*p+1)+1))*x^n,x],x] /;
FreeQ[{a,b,c,d,e,f,p},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && GtQ[m,n-1] && NeQ[m+n(2*p+1)+1,0] && IntegerQ[p]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)*(a_+c_.*x_^n2_)^p_,x_Symbol] :=
  e*f^(n-1)*(f*x)^(m-n+1)*(a+c*x^(2*n))^(p+1)/(c*(m+n(2*p+1)+1)) - 
  f^n/(c*(m+n(2*p+1)+1))*Int[(f*x)^(m-n)*(a+c*x^(2*n))^p*(a*e*(m-n+1)-c*d*(m+n(2*p+1)+1)*x^n),x] /;
FreeQ[{a,c,d,e,f,p},x] && EqQ[n2,2*n] && IGtQ[n,0] && GtQ[m,n-1] && NeQ[m+n(2*p+1)+1,0] && IntegerQ[p]

4:  ∫(((f x))^m)(d+e (x^n))(((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m<-1

Derivation: Trinomial recurrence 3b

Rule 1.2.3.4.6.1.4.4: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ m<-1, then

∫(((f x))^m) (d+e (x^n))(((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  
((d (((f x))^(m+1)) (((a+b (x^n)+c (x^(2 n))))^(p+1)))/(a f (m+1)))+
(1/(a (f^n) (m+1))) ∫(((f x))^(m+n)) (((a+b (x^n)+c (x^(2 n))))^p) (a e (m+1)-b d (m+n(p+1)+1)-c d(m+2n(p+1)+1) (x^n))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)*(a_+b_.*x_^n_+c_.*x_^n2_)^p_,x_Symbol] :=
  d*(f*x)^(m+1)*(a+b*x^n+c*x^(2*n))^(p+1)/(a*f*(m+1)) + 
  1/(a*f^n*(m+1))*Int[(f*x)^(m+n)*(a+b*x^n+c*x^(2*n))^p*Simp[a*e*(m+1)-b*d*(m+n*(p+1)+1)-c*d*(m+2*n(p+1)+1)*x^n,x],x] /;
FreeQ[{a,b,c,d,e,f,p},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && LtQ[m,-1] && IntegerQ[p]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)*(a_+c_.*x_^n2_)^p_,x_Symbol] :=
  d*(f*x)^(m+1)*(a+c*x^(2*n))^(p+1)/(a*f*(m+1)) + 
  1/(a*f^n*(m+1))*Int[(f*x)^(m+n)*(a+c*x^(2*n))^p*(a*e*(m+1)-c*d*(m+2*n(p+1)+1)*x^n),x] /;
FreeQ[{a,c,d,e,f,p},x] && EqQ[n2,2*n] && IGtQ[n,0] && LtQ[m,-1] && IntegerQ[p]

5.  ∫(((((f x))^m) (d+e (x^n)))/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])

1:  ∫(((((f x))^m) (d+e (x^n)))/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c<0 ∧ (n/2)∈(SuperPlus[ℤ]) ∧ 0<m<n ∧ a c>0

Derivation: Algebraic expansion

Basis: Let q=(Sqrt[a c]) and r=(Sqrt[2c q-b c]), then ((d+e (z^2))/(a+b (z^2)+c (z^4)))=(c/(2 q r))((d r-(c d-e q) z)/(q-r z+c (z^2)))+(c/(2 q r))((d r+(c d-e q) z)/(q+r z+c (z^2)))

Rule 1.2.3.4.6.1.4.5.1: If  (b^2)-4 a c<0 ∧ (n/2)∈(SuperPlus[ℤ]) ∧ 0<m<n ∧ a c>0, let q=(Sqrt[a c]), if  2c q-b c>0, let r=(Sqrt[2c q-b c]), then

∫(((((f x))^m) (d+e (x^n)))/(a+b (x^n)+c (x^(2n))))dx  ⟶  (c/(2 q r))∫(((((f x))^m)(d r-(c d-e q) (x^(n/2))))/(q-r (x^(n/2))+c (x^n)))dx+(c/(2 q r))∫(((((f x))^m)(d r+(c d-e q) (x^(n/2))))/(q+r (x^(n/2))+c (x^n)))dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^n_)/(a_+b_.*x_^n_+c_.*x_^n2_),x_Symbol] :=
  With[{q=Rt[a*c,2]},
  With[{r=Rt[2*c*q-b*c,2]},
  c/(2*q*r)*Int[(f*x)^m*Simp[d*r-(c*d-e*q)*x^(n/2),x]/(q-r*x^(n/2)+c*x^n),x] + 
  c/(2*q*r)*Int[(f*x)^m*Simp[d*r+(c*d-e*q)*x^(n/2),x]/(q+r*x^(n/2)+c*x^n),x]] /;
 Not[LtQ[2*c*q-b*c,0]]] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[n2,2*n] && LtQ[b^2-4*a*c,0] && IntegersQ[m,n/2] && LtQ[0,m,n] && PosQ[a*c]

Int[(f_.*x_)^m_*(d_+e_.*x_^n_)/(a_+c_.*x_^n2_),x_Symbol] :=
  With[{q=Rt[a*c,2]},
  With[{r=Rt[2*c*q,2]},
  c/(2*q*r)*Int[(f*x)^m*Simp[d*r-(c*d-e*q)*x^(n/2),x]/(q-r*x^(n/2)+c*x^n),x] + 
  c/(2*q*r)*Int[(f*x)^m*Simp[d*r+(c*d-e*q)*x^(n/2),x]/(q+r*x^(n/2)+c*x^n),x]] /;
 Not[LtQ[2*c*q,0]]] /;
FreeQ[{a,c,d,e,f},x] && EqQ[n2,2*n] && GtQ[a*c,0] && IntegersQ[m,n/2] && LtQ[0,m,n]

2:  ∫(((((f x))^m)(d+e (x^n)))/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c<0 ∧ (n/2)-1∈(SuperPlus[ℤ])∧ a c>0

Derivation: Algebraic expansion

Basis: Let q=(Sqrt[a c]) and r=(Sqrt[2c q-b c]), then ((d+e (z^2))/(a+b (z^2)+c (z^4)))==(c/(2 q r))((d r-(c d-e q) z)/(q-r z+c (z^2)))+(c/(2 q r))((d r+(c d-e q) z)/(q+r z+c (z^2)))

Rule 1.2.3.4.6.1.4.5.2: If  (b^2)-4 a c<0 ∧ (n/2)-1∈(SuperPlus[ℤ])∧ a c>0, let q=(Sqrt[a c]), if  2c q-b c>0, let r=(Sqrt[2c q-b c]), then

∫(((((f x))^m)(d+e (x^n)))/(a+b (x^n)+c (x^(2n))))dx  ⟶  (c/(2 q r))∫(((((f x))^m)(d r-(c d-e q) (x^(n/2))))/(q-r (x^(n/2))+c (x^n)))dx+(c/(2 q r))∫(((((f x))^m)(d r+(c d-e q) (x^(n/2))))/(q+r (x^(n/2))+c (x^n)))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)/(a_+b_.*x_^n_+c_.*x_^n2_),x_Symbol] :=
  With[{q=Rt[a*c,2]},
  With[{r=Rt[2*c*q-b*c,2]},
  c/(2*q*r)*Int[(f*x)^m*(d*r-(c*d-e*q)*x^(n/2))/(q-r*x^(n/2)+c*x^n),x] + 
  c/(2*q*r)*Int[(f*x)^m*(d*r+(c*d-e*q)*x^(n/2))/(q+r*x^(n/2)+c*x^n),x]] /;
 Not[LtQ[2*c*q-b*c,0]]] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[n2,2*n] && LtQ[b^2-4*a*c,0] && IGtQ[n/2,1] && PosQ[a*c]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)/(a_+c_.*x_^n2_),x_Symbol] :=
  With[{q=Rt[a*c,2]},
  With[{r=Rt[2*c*q,2]},
  c/(2*q*r)*Int[(f*x)^m*(d*r-(c*d-e*q)*x^(n/2))/(q-r*x^(n/2)+c*x^n),x] + 
  c/(2*q*r)*Int[(f*x)^m*(d*r+(c*d-e*q)*x^(n/2))/(q+r*x^(n/2)+c*x^n),x]] /;
 Not[LtQ[2*c*q,0]]] /;
FreeQ[{a,c,d,e,f,m},x] && EqQ[n2,2*n] && IGtQ[n/2,1] && GtQ[a*c,0]

3:  ∫(((((f x))^m) (d+e (x^n)))/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: Let q->(Sqrt[(b^2)-4 a c]), then ((d+e z)/(a+b z+c (z^2)))==((e/2)+((2 c d-b e)/(2 q))) (1/((b/2)-(q/2)+c z))+((e/2)-((2 c d-b e)/(2 q))) (1/((b/2)+(q/2)+c z))

Rule 1.2.3.4.6.1.4.5.3: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ]), let q->(Sqrt[(b^2)-4 a c]), then

∫(((((f x))^m) (d+e (x^n)))/(a+b (x^n)+c (x^(2 n))))dx  ⟶  ((e/2)+((2 c d-b e)/(2 q)))∫((((f x))^m)/((b/2)-(q/2)+c (x^n)))dx+((e/2)-((2 c d-b e)/(2 q)))∫((((f x))^m)/((b/2)+(q/2)+c (x^n)))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)/(a_+b_.*x_^n_+c_.*x_^n2_),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  (e/2+(2*c*d-b*e)/(2*q))*Int[(f*x)^m/(b/2-q/2+c*x^n),x] + (e/2-(2*c*d-b*e)/(2*q))*Int[(f*x)^m/(b/2+q/2+c*x^n),x]] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)/(a_+c_.*x_^n2_),x_Symbol] :=
  With[{q=Rt[-a*c,2]},
  -(e/2+c*d/(2*q))*Int[(f*x)^m/(q-c*x^n),x] + (e/2-c*d/(2*q))*Int[(f*x)^m/(q+c*x^n),x]] /;
FreeQ[{a,c,d,e,f,m},x] && EqQ[n2,2*n] && IGtQ[n,0]

5.  ∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])

1.  ∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∈ℤ

1:  ∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∈ℤ ∧ m∈ℤ

Derivation: Algebraic expansion

Rule 1.2.3.4.6.1.5.1.1: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∈ℤ ∧ m∈ℤ, then

∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2 n))))dx  ⟶  ∫ExpandIntegrand[(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2 n)))),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_./(a_+b_.*x_^n_+c_.*x_^n2_.),x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m*(d+e*x^n)^q/(a+b*x^n+c*x^(2*n)),x],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && IntegerQ[q] && IntegerQ[m]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_./(a_+c_.*x_^n2_.),x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m*(d+e*x^n)^q/(a+c*x^(2*n)),x],x] /;
FreeQ[{a,c,d,e,f,m},x] && EqQ[n2,2*n] && IGtQ[n,0] && IntegerQ[q] && IntegerQ[m]

2:  ∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∈ℤ ∧ m∉ℤ

Derivation: Algebraic expansion

Rule 1.2.3.4.6.1.5.1.2: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∈ℤ ∧ m∉ℤ, then

∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2 n))))dx  ⟶  ∫(((f x))^m) ExpandIntegrand[((((d+e (x^n)))^q)/(a+b (x^n)+c (x^(2 n)))),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_./(a_+b_.*x_^n_+c_.*x_^n2_.),x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m,(d+e*x^n)^q/(a+b*x^n+c*x^(2*n)),x],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && IntegerQ[q] && Not[IntegerQ[m]]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_./(a_+c_.*x_^n2_.),x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m,(d+e*x^n)^q/(a+c*x^(2*n)),x],x] /;
FreeQ[{a,c,d,e,f,m},x] && EqQ[n2,2*n] && IGtQ[n,0] && IntegerQ[q] && Not[IntegerQ[m]]

2.  ∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2 n))))dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ

1.  ∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ ∧ q>0

1.  ∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ ∧ q>0 ∧ m>n-1

1:  ∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ ∧ q>0 ∧ m>2n-1

Reference: Algebraic expansion

Basis: ((d+e z)/(a+b z+c (z^2)))==((c d-b e+c e z)/((c^2) (z^2)))-((a (c d-b e)+(b c d-(b^2) e+a c e) z)/((c^2) (z^2) (a+b z+c (z^2))))

Rule 1.2.3.4.6.1.5.2.1.1.1: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ ∧ q>0 ∧ m>2n-1, then

∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  ⟶  
((f^(2 n))/(c^2))∫(((f x))^(m-2 n))(c d-b e+c e (x^n))(((d+e (x^n)))^(q-1))dx-((f^(2 n))/(c^2))∫(((((f x))^(m-2 n)) (((d+e (x^n)))^(q-1)) (a (c d-b e)+(b c d-(b^2) e+a c e) (x^n)))/(a+b (x^n)+c (x^(2n))))dx

Program code:

Int[(f_.*x_)^m_.*(d_.+e_.*x_^n_)^q_/(a_+b_.*x_^n_+c_.*x_^n2_.),x_Symbol] :=
  f^(2*n)/c^2*Int[(f*x)^(m-2*n)*(c*d-b*e+c*e*x^n)*(d+e*x^n)^(q-1),x] - 
  f^(2*n)/c^2*Int[(f*x)^(m-2*n)*(d+e*x^n)^(q-1)*Simp[a*(c*d-b*e)+(b*c*d-b^2*e+a*c*e)*x^n,x]/(a+b*x^n+c*x^(2*n)),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && Not[IntegerQ[q]] && GtQ[q,0] && GtQ[m,2*n-1]

Int[(f_.*x_)^m_.*(d_.+e_.*x_^n_)^q_/(a_+c_.*x_^n2_.),x_Symbol] :=
  f^(2*n)/c*Int[(f*x)^(m-2*n)*(d+e*x^n)^q,x] - 
  a*f^(2*n)/c*Int[(f*x)^(m-2*n)*(d+e*x^n)^q/(a+c*x^(2*n)),x] /;
FreeQ[{a,c,d,e,f,q},x] && EqQ[n2,2*n] && IGtQ[n,0] && Not[IntegerQ[q]] && GtQ[m,2*n-1]

2:  ∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ ∧ q>0 ∧ n-1<m≤2n-1

Reference: Algebraic expansion

Basis: ((d+e z)/(a+b z+c (z^2)))==(e/(c z))-((a e-(c d-b e) z)/(c z (a+b z+c (z^2))))

Rule 1.2.3.4.6.1.5.2.1.1.2: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ ∧ q>0 ∧ n-1<m≤2n-1, then

∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  ⟶  ((e (f^n))/c)∫(((f x))^(m-n))(((d+e (x^n)))^(q-1))dx-((f^n)/c)∫(((((f x))^(m-n)) (((d+e (x^n)))^(q-1)) (a e-(c d-b e) (x^n)))/(a+b (x^n)+c (x^(2n))))dx

Program code:

Int[(f_.*x_)^m_.*(d_.+e_.*x_^n_)^q_/(a_+b_.*x_^n_+c_.*x_^n2_.),x_Symbol] :=
  e*f^n/c*Int[(f*x)^(m-n)*(d+e*x^n)^(q-1),x] - 
  f^n/c*Int[(f*x)^(m-n)*(d+e*x^n)^(q-1)*Simp[a*e-(c*d-b*e)*x^n,x]/(a+b*x^n+c*x^(2*n)),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && Not[IntegerQ[q]] && GtQ[q,0] && GtQ[m,n-1] && LeQ[m,2n-1]

Int[(f_.*x_)^m_.*(d_.+e_.*x_^n_)^q_/(a_+c_.*x_^n2_.),x_Symbol] :=
  e*f^n/c*Int[(f*x)^(m-n)*(d+e*x^n)^(q-1),x] - 
  f^n/c*Int[(f*x)^(m-n)*(d+e*x^n)^(q-1)*Simp[a*e-c*d*x^n,x]/(a+c*x^(2*n)),x] /;
FreeQ[{a,c,d,e,f},x] && EqQ[n2,2*n] && IGtQ[n,0] && Not[IntegerQ[q]] && GtQ[q,0] && GtQ[m,n-1] && LeQ[m,2n-1]

2:  ∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ ∧ q>0 ∧ m<0

Reference: Algebraic expansion

Basis: ((d+e z)/(a+b z+c (z^2)))==(d/a)-((z (b d-a e+c d z))/(a (a+b z+c (z^2))))

Rule 1.2.3.4.6.1.5.2.1.2: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ ∧ q>0 ∧ m<0, then

∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  ⟶  (d/a)∫(((f x))^m) (((d+e (x^n)))^(q-1))dx-(1/(a (f^n)))∫(((((f x))^(m+n)) (((d+e (x^n)))^(q-1)) (b d-a e+c d (x^n)))/(a+b (x^n)+c (x^(2 n))))dx

Program code:

Int[(f_.*x_)^m_*(d_.+e_.*x_^n_)^q_/(a_+b_.*x_^n_+c_.*x_^n2_.),x_Symbol] :=
  d/a*Int[(f*x)^m*(d+e*x^n)^(q-1),x] - 
  1/(a*f^n)*Int[(f*x)^(m+n)*(d+e*x^n)^(q-1)*Simp[b*d-a*e+c*d*x^n,x]/(a+b*x^n+c*x^(2*n)),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && Not[IntegerQ[q]] && GtQ[q,0] && LtQ[m,0]

Int[(f_.*x_)^m_*(d_.+e_.*x_^n_)^q_/(a_+c_.*x_^n2_.),x_Symbol] :=
  d/a*Int[(f*x)^m*(d+e*x^n)^(q-1),x] + 
  1/(a*f^n)*Int[(f*x)^(m+n)*(d+e*x^n)^(q-1)*Simp[a*e-c*d*x^n,x]/(a+c*x^(2*n)),x] /;
FreeQ[{a,c,d,e,f},x] && EqQ[n2,2*n] && IGtQ[n,0] && Not[IntegerQ[q]] && GtQ[q,0] && LtQ[m,0]

2.  ∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ ∧ q<-1

1.  ∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ ∧ q<-1 ∧ m>n-1

1:  ∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ ∧ q<-1 ∧ m>2 n-1

Reference: Algebraic expansion

Basis: (1/(a+b z+c (z^2)))==((d^2)/((c (d^2)-b d e+a (e^2)) (z^2)))-(((d+e z) (a d+(b d-a e) z))/((c (d^2)-b d e+a (e^2)) (z^2) (a+b z+c (z^2))))

Rule 1.2.3.4.6.1.5.2.2.1.1: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ ∧ q<-1 ∧ m>2 n-1, then

∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  ⟶  (((d^2) (f^(2 n)))/(c (d^2)-b d e+a (e^2)))∫(((f x))^(m-2 n)) (((d+e (x^n)))^q)dx-((f^(2 n))/(c (d^2)-b d e+a (e^2)))∫(((((f x))^(m-2 n)) (((d+e (x^n)))^(q+1)) (a d+(b d-a e) (x^n)))/(a+b (x^n)+c (x^(2 n))))dx

Program code:

Int[(f_.*x_)^m_.*(d_.+e_.*x_^n_)^q_/(a_+b_.*x_^n_+c_.*x_^n2_.),x_Symbol] :=
  d^2*f^(2*n)/(c*d^2-b*d*e+a*e^2)*Int[(f*x)^(m-2*n)*(d+e*x^n)^q,x] - 
  f^(2*n)/(c*d^2-b*d*e+a*e^2)*Int[(f*x)^(m-2*n)*(d+e*x^n)^(q+1)*Simp[a*d+(b*d-a*e)*x^n,x]/(a+b*x^n+c*x^(2*n)),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && Not[IntegerQ[q]] && LtQ[q,-1] && GtQ[m,2*n-1]

Int[(f_.*x_)^m_.*(d_.+e_.*x_^n_)^q_/(a_+c_.*x_^n2_.),x_Symbol] :=
  d^2*f^(2*n)/(c*d^2+a*e^2)*Int[(f*x)^(m-2*n)*(d+e*x^n)^q,x] - 
  a*f^(2*n)/(c*d^2+a*e^2)*Int[(f*x)^(m-2*n)*(d+e*x^n)^(q+1)*(d-e*x^n)/(a+c*x^(2*n)),x] /;
FreeQ[{a,c,d,e,f},x] && EqQ[n2,2*n] && IGtQ[n,0] && Not[IntegerQ[q]] && LtQ[q,-1] && GtQ[m,2*n-1]

2:  ∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ ∧ q<-1 ∧ n-1<m≤2n-1

Reference: Algebraic expansion

Basis: (1/(a+b z+c (z^2)))==-((d e)/((c (d^2)-b d e+a (e^2)) z))+(((d+e z) (a e+c d z))/((c (d^2)-b d e+a (e^2)) z (a+b z+c (z^2))))

Rule 1.2.3.4.6.1.5.2.2.1.2: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ ∧ q<-1 ∧ n-1<m≤2n-1, then

∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  ⟶  -((d e (f^n))/(c (d^2)-b d e+a (e^2)))∫(((f x))^(m-n)) (((d+e (x^n)))^q)dx+((f^n)/(c (d^2)-b d e+a (e^2)))∫(((((f x))^(m-n)) (((d+e (x^n)))^(q+1)) (a e+c d (x^n)))/(a+b (x^n)+c (x^(2 n))))dx

Program code:

Int[(f_.*x_)^m_.*(d_.+e_.*x_^n_)^q_/(a_+b_.*x_^n_+c_.*x_^n2_.),x_Symbol] :=
  -d*e*f^n/(c*d^2-b*d*e+a*e^2)*Int[(f*x)^(m-n)*(d+e*x^n)^q,x] + 
  f^n/(c*d^2-b*d*e+a*e^2)*Int[(f*x)^(m-n)*(d+e*x^n)^(q+1)*Simp[a*e+c*d*x^n,x]/(a+b*x^n+c*x^(2*n)),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && Not[IntegerQ[q]] && LtQ[q,-1] && GtQ[m,n-1] && LeQ[m,2*n-1]

Int[(f_.*x_)^m_.*(d_.+e_.*x_^n_)^q_/(a_+c_.*x_^n2_.),x_Symbol] :=
  -d*e*f^n/(c*d^2+a*e^2)*Int[(f*x)^(m-n)*(d+e*x^n)^q,x] + 
  f^n/(c*d^2+a*e^2)*Int[(f*x)^(m-n)*(d+e*x^n)^(q+1)*Simp[a*e+c*d*x^n,x]/(a+c*x^(2*n)),x] /;
FreeQ[{a,c,d,e,f},x] && EqQ[n2,2*n] && IGtQ[n,0] && Not[IntegerQ[q]] && LtQ[q,-1] && GtQ[m,n-1] && LeQ[m,2*n-1]

2:  ∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ ∧ q<-1

Derivation: Algebraic expansion

Basis: (1/(a+b z+c (z^2)))==((e^2)/(c (d^2)-b d e+a (e^2)))+(((d+e z) (c d-b e-c e z))/((c (d^2)-b d e+a (e^2)) (a+b z+c (z^2))))

Rule 1.2.3.4.6.1.5.2.2.2: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ ∧ q<-1, then

∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  ⟶  ((e^2)/(c (d^2)-b d e+a (e^2)))∫(((f x))^m) (((d+e (x^n)))^q)dx+(1/(c (d^2)-b d e+a (e^2)))∫(((((f x))^m) (((d+e (x^n)))^(q+1)) (c d-b e-c e (x^n)))/(a+b (x^n)+c (x^(2n))))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_/(a_+b_.*x_^n_+c_.*x_^n2_),x_Symbol] :=
  e^2/(c*d^2-b*d*e+a*e^2)*Int[(f*x)^m*(d+e*x^n)^q,x] + 
  1/(c*d^2-b*d*e+a*e^2)*Int[(f*x)^m*(d+e*x^n)^(q+1)*Simp[c*d-b*e-c*e*x^n,x]/(a+b*x^n+c*x^(2*n)),x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && Not[IntegerQ[q]] && LtQ[q,-1]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_/(a_+c_.*x_^n2_),x_Symbol] :=
  e^2/(c*d^2+a*e^2)*Int[(f*x)^m*(d+e*x^n)^q,x] + 
  c/(c*d^2+a*e^2)*Int[(f*x)^m*(d+e*x^n)^(q+1)*(d-e*x^n)/(a+c*x^(2*n)),x] /;
FreeQ[{a,c,d,e,f,m},x] && EqQ[n2,2*n] && IGtQ[n,0] && Not[IntegerQ[q]] && LtQ[q,-1]

3:  ∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ ∧ m∈ℤ

Derivation: Algebraic expansion

Basis: If  q=(Sqrt[(b^2)-4a c]), then (1/(a+b z+c (z^2)))==((2c)/(q(b-q+2 c z)))-((2c)/(q(b+q+2 c z)))

Rule 1.2.3.4.6.1.5.2.3: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ ∧ m∈ℤ, then

∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  ⟶  ∫(((d+e (x^n)))^q) ExpandIntegrand[((((f x))^m)/(a+b (x^n)+c (x^(2n)))),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_/(a_+b_.*x_^n_+c_.*x_^n2_.),x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^n)^q,(f*x)^m/(a+b*x^n+c*x^(2*n)),x],x] /;
FreeQ[{a,b,c,d,e,f,q,n},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && Not[IntegerQ[q]] && IntegerQ[m]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_/(a_+c_.*x_^n2_.),x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^n)^q,(f*x)^m/(a+c*x^(2*n)),x],x] /;
FreeQ[{a,c,d,e,f,q,n},x] && EqQ[n2,2*n] && IGtQ[n,0] && Not[IntegerQ[q]] && IntegerQ[m]

4:  ∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ ∧ m∉ℤ

Derivation: Algebraic expansion

Basis: If  q=(Sqrt[(b^2)-4a c]), then (1/(a+b z+c (z^2)))==((2c)/(q(b-q+2 c z)))-((2c)/(q(b+q+2 c z)))

Rule 1.2.3.4.6.1.5.2.4: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ q∉ℤ ∧ m∉ℤ, then

∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  ⟶  ∫(((f x))^m) (((d+e (x^n)))^q) ExpandIntegrand[(1/(a+b (x^n)+c (x^(2n)))),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_/(a_+b_.*x_^n_+c_.*x_^n2_.),x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m*(d+e*x^n)^q,1/(a+b*x^n+c*x^(2*n)),x],x] /;
FreeQ[{a,b,c,d,e,f,m,q,n},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && Not[IntegerQ[q]] && Not[IntegerQ[m]]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_/(a_+c_.*x_^n2_.),x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m*(d+e*x^n)^q,1/(a+c*x^(2*n)),x],x] /;
FreeQ[{a,c,d,e,f,m,q,n},x] && EqQ[n2,2*n] && IGtQ[n,0] && Not[IntegerQ[q]] && Not[IntegerQ[m]]

6.  ∫(((((f x))^m) (((a+b (x^n)+c (x^(2 n))))^p))/(d+e (x^n)))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])

1.  ∫(((((f x))^m) (((a+b (x^n)+c (x^(2 n))))^p))/(d+e (x^n)))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p>0 ∧ m<0

1:  ∫(((((f x))^m) (((a+b (x^n)+c (x^(2 n))))^p))/(d+e (x^n)))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p>0 ∧ m<-n

Reference: Algebraic expansion

Basis: ((a+b z+c (z^2))/(d+e z))==((a d+(b d-a e) z)/(d^2))+(((c (d^2)-b d e+a (e^2)) (z^2))/((d^2) (d+e z)))

Rule 1.2.3.4.6.1.6.1.1: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p>0 ∧ m<-n, then

∫(((((f x))^m) (((a+b (x^n)+c (x^(2 n))))^p))/(d+e (x^n)))dx  ⟶  
(1/(d^2))∫(((f x))^m) (a d+(b d-a e) (x^n)) (((a+b (x^n)+c (x^(2 n))))^(p-1))dx+((c (d^2)-b d e+a (e^2))/((d^2) (f^(2 n))))∫(((((f x))^(m+2 n)) (((a+b (x^n)+c (x^(2 n))))^(p-1)))/(d+e (x^n)))dx

Program code:

Int[(f_.*x_)^m_*(a_.+b_.*x_^n_+c_.*x_^n2_.)^p_./(d_.+e_.*x_^n_),x_Symbol] :=
  1/d^2*Int[(f*x)^m*(a*d+(b*d-a*e)*x^n)*(a+b*x^n+c*x^(2*n))^(p-1),x] + 
  (c*d^2-b*d*e+a*e^2)/(d^2*f^(2*n))*Int[(f*x)^(m+2*n)*(a+b*x^n+c*x^(2*n))^(p-1)/(d+e*x^n),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && GtQ[p,0] && LtQ[m,-n]

Int[(f_.*x_)^m_*(a_+c_.*x_^n2_.)^p_./(d_.+e_.*x_^n_),x_Symbol] :=
  a/d^2*Int[(f*x)^m*(d-e*x^n)*(a+c*x^(2*n))^(p-1),x] + 
  (c*d^2+a*e^2)/(d^2*f^(2*n))*Int[(f*x)^(m+2*n)*(a+c*x^(2*n))^(p-1)/(d+e*x^n),x] /;
FreeQ[{a,c,d,e,f},x] && EqQ[n2,2*n] && IGtQ[n,0] && GtQ[p,0] && LtQ[m,-n]

2:  ∫(((((f x))^m) (((a+b (x^n)+c (x^(2 n))))^p))/(d+e (x^n)))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p>0 ∧ m<0

Reference: Algebraic expansion

Basis: ((a+b z+c (z^2))/(d+e z))==((a e+c d z)/(d e))-(((c (d^2)-b d e+a (e^2))z)/(d e(d+e z)))

Rule 1.2.3.4.6.1.6.1.2: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p>0 ∧ m<0, then

∫(((((f x))^m) (((a+b (x^n)+c (x^(2 n))))^p))/(d+e (x^n)))dx  ⟶  
(1/(d e))∫(((f x))^m) (a e+c d (x^n)) (((a+b (x^n)+c (x^(2 n))))^(p-1))dx-((c (d^2)-b d e+a (e^2))/(d e (f^n)))∫(((((f x))^(m+n)) (((a+b (x^n)+c (x^(2 n))))^(p-1)))/(d+e (x^n)))dx

Program code:

Int[(f_.*x_)^m_*(a_.+b_.*x_^n_+c_.*x_^n2_.)^p_./(d_.+e_.*x_^n_),x_Symbol] :=
  1/(d*e)*Int[(f*x)^m*(a*e+c*d*x^n)*(a+b*x^n+c*x^(2*n))^(p-1),x] - 
  (c*d^2-b*d*e+a*e^2)/(d*e*f^n)*Int[(f*x)^(m+n)*(a+b*x^n+c*x^(2*n))^(p-1)/(d+e*x^n),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && GtQ[p,0] && LtQ[m,0]

Int[(f_.*x_)^m_*(a_+c_.*x_^n2_.)^p_./(d_.+e_.*x_^n_),x_Symbol] :=
  1/(d*e)*Int[(f*x)^m*(a*e+c*d*x^n)*(a+c*x^(2*n))^(p-1),x] - 
  (c*d^2+a*e^2)/(d*e*f^n)*Int[(f*x)^(m+n)*(a+c*x^(2*n))^(p-1)/(d+e*x^n),x] /;
FreeQ[{a,c,d,e,f},x] && EqQ[n2,2*n] && IGtQ[n,0] && GtQ[p,0] && LtQ[m,0]

2.  ∫(((((f x))^m) (((a+b (x^n)+c (x^(2 n))))^p))/(d+e (x^n)))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ m>0

1:  ∫(((((f x))^m) (((a+b (x^n)+c (x^(2 n))))^p))/(d+e (x^n)))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ m>n

Reference: Algebraic expansion

Basis: ((z^2)/(d+e z))==-((a d+(b d-a e) z)/(c (d^2)-b d e+a (e^2)))+(((d^2)(a+b z+c (z^2)))/((c (d^2)-b d e+a (e^2)) (d+e z)))

Rule 1.2.3.4.6.1.6.2.1: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ m>n, then

∫(((((f x))^m) (((a+b (x^n)+c (x^(2 n))))^p))/(d+e (x^n)))dx  ⟶  
-((f^(2 n))/(c (d^2)-b d e+a (e^2)))∫(((f x))^(m-2 n)) (a d+(b d-a e) (x^n)) (((a+b (x^n)+c (x^(2 n))))^p)dx+(((d^2) (f^(2 n)))/(c (d^2)-b d e+a (e^2)))∫(((((f x))^(m-2 n)) (((a+b (x^n)+c (x^(2 n))))^(p+1)))/(d+e (x^n)))dx

Program code:

Int[(f_.*x_)^m_.*(a_.+b_.*x_^n_+c_.*x_^n2_.)^p_/(d_.+e_.*x_^n_),x_Symbol] :=
  -f^(2*n)/(c*d^2-b*d*e+a*e^2)*Int[(f*x)^(m-2*n)*(a*d+(b*d-a*e)*x^n)*(a+b*x^n+c*x^(2*n))^p,x] + 
  d^2*f^(2*n)/(c*d^2-b*d*e+a*e^2)*Int[(f*x)^(m-2*n)*(a+b*x^n+c*x^(2*n))^(p+1)/(d+e*x^n),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && LtQ[p,-1] && GtQ[m,n]

Int[(f_.*x_)^m_.*(a_+c_.*x_^n2_.)^p_/(d_.+e_.*x_^n_),x_Symbol] :=
  -a*f^(2*n)/(c*d^2+a*e^2)*Int[(f*x)^(m-2*n)*(d-e*x^n)*(a+c*x^(2*n))^p,x] + 
  d^2*f^(2*n)/(c*d^2+a*e^2)*Int[(f*x)^(m-2*n)*(a+c*x^(2*n))^(p+1)/(d+e*x^n),x] /;
FreeQ[{a,c,d,e,f},x] && EqQ[n2,2*n] && IGtQ[n,0] && LtQ[p,-1] && GtQ[m,n]

2:  ∫(((((f x))^m) (((a+b (x^n)+c (x^(2 n))))^p))/(d+e (x^n)))dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ m>0

Reference: Algebraic expansion

Basis: (z/(d+e z))==((a e+c d z)/(c (d^2)-b d e+a (e^2)))-((d e(a+b z+c (z^2)))/((c (d^2)-b d e+a (e^2)) (d+e z)))

Rule 1.2.3.4.6.1.6.2.2: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ p<-1 ∧ m>0, then

∫(((((f x))^m) (((a+b (x^n)+c (x^(2 n))))^p))/(d+e (x^n)))dx  ⟶  
((f^n)/(c (d^2)-b d e+a (e^2)))∫(((f x))^(m-n)) (a e+c d (x^n)) (((a+b (x^n)+c (x^(2 n))))^p)dx-((d e (f^n))/(c (d^2)-b d e+a (e^2)))∫(((((f x))^(m-n)) (((a+b (x^n)+c (x^(2 n))))^(p+1)))/(d+e (x^n)))dx

Program code:

Int[(f_.*x_)^m_.*(a_.+b_.*x_^n_+c_.*x_^n2_.)^p_/(d_.+e_.*x_^n_),x_Symbol] :=
  f^n/(c*d^2-b*d*e+a*e^2)*Int[(f*x)^(m-n)*(a*e+c*d*x^n)*(a+b*x^n+c*x^(2*n))^p,x] - 
  d*e*f^n/(c*d^2-b*d*e+a*e^2)*Int[(f*x)^(m-n)*(a+b*x^n+c*x^(2*n))^(p+1)/(d+e*x^n),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && LtQ[p,-1] && GtQ[m,0]

Int[(f_.*x_)^m_.*(a_+c_.*x_^n2_.)^p_/(d_.+e_.*x_^n_),x_Symbol] :=
  f^n/(c*d^2+a*e^2)*Int[(f*x)^(m-n)*(a*e+c*d*x^n)*(a+c*x^(2*n))^p,x] - 
  d*e*f^n/(c*d^2+a*e^2)*Int[(f*x)^(m-n)*(a+c*x^(2*n))^(p+1)/(d+e*x^n),x] /;
FreeQ[{a,c,d,e,f},x] && EqQ[n2,2*n] && IGtQ[n,0] && LtQ[p,-1] && GtQ[m,0]

7:  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ (q∈(SuperPlus[ℤ]) ∨ (m|q)∈ℤ)

Derivation: Algebraic expansion

Rule 1.2.3.4.6.1.7: If  (b^2)-4 a c≠0 ∧ n∈(SuperPlus[ℤ])∧ (q∈(SuperPlus[ℤ]) ∨ (m|q)∈ℤ) , then

∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ∫(((a+b (x^n)+c (x^(2 n))))^p) ExpandIntegrand[(((f x))^m) (((d+e (x^n)))^q),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*x^n+c*x^(2*n))^p,(f*x)^m(d+e*x^n)^q,x],x] /;
FreeQ[{a,b,c,d,e,f,m,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[n,0] && (IGtQ[q,0] || IntegersQ[m,q])

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+c*x^(2*n))^p,(f*x)^m(d+e*x^n)^q,x],x] /;
FreeQ[{a,c,d,e,f,m,q},x] && EqQ[n2,2*n] && IGtQ[n,0] && IGtQ[q,0]

2.  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperMinus[ℤ])

1.  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperMinus[ℤ])∧ m∈ℚ

1:  ∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperMinus[ℤ])∧ m∈ℤ

Derivation: Integration by substitution

Basis: F[x]==-Subst[((F[(x^(-1))] )/(x^2)),x,(1/x)](∂_x)(1/x)

Rule 1.2.3.4.6.2.1.1: If  (b^2)-4 a c≠0 ∧ n∈(SuperMinus[ℤ])∧ m∈ℤ, then

∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  -Subst[∫(((((d+e (x^(-n))))^q) (((a+b (x^(-n))+c (x^(-2 n))))^p))/(x^(m+2)))dx,x,(1/x)]

Program code:

Int[x_^m_.*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  -Subst[Int[(d+e*x^(-n))^q*(a+b*x^(-n)+c*x^(-2*n))^p/x^(m+2),x],x,1/x] /;
FreeQ[{a,b,c,d,e,p,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && ILtQ[n,0] && IntegerQ[m]

Int[x_^m_.*(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_.)^p_,x_Symbol] :=
  -Subst[Int[(d+e*x^(-n))^q*(a+c*x^(-2*n))^p/x^(m+2),x],x,1/x] /;
FreeQ[{a,c,d,e,p,q},x] && EqQ[n2,2*n] && ILtQ[n,0] && IntegerQ[m]

2:  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperMinus[ℤ])∧ m∈𝔽

Derivation: Integration by substitution

Basis: If  n∈ℤ ∧ g>1, then (((f x))^m) F[(x^n)]==-(g/f)Subst[ ((F[(f^(-n)) (x^(-g n))])/(x^(g (m+1)+1))),x,(1/(((f x))^(1/g)))] (∂_x)(1/(((f x))^(1/g)))

Rule 1.2.3.4.6.2.1.2: If  (b^2)-4 a c≠0 ∧ n∈(SuperMinus[ℤ])∧ m∈𝔽, let g=Denominator[m], then

∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  -(g/f)Subst[∫(((((d+e (f^(-n)) (x^(-g n))))^q) (((a+b (f^(-n)) (x^(-g n))+c (f^(-2 n)) (x^(-2 g n))))^p))/(x^(g (m+1)+1)))dx,x,(1/(((f x))^(1/g)))]

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  With[{g=Denominator[m]},
  -g/f*Subst[Int[(d+e*f^(-n)*x^(-g*n))^q*(a+b*f^(-n)*x^(-g*n)+c*f^(-2*n)*x^(-2*g*n))^p/x^(g*(m+1)+1),x],x,1/(f*x)^(1/g)]] /;
FreeQ[{a,b,c,d,e,f,p,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && ILtQ[n,0] && FractionQ[m]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_.)^p_,x_Symbol] :=
  With[{g=Denominator[m]},
  -g/f*Subst[Int[(d+e*f^(-n)*x^(-g*n))^q*(a+c*f^(-2*n)*x^(-2*g*n))^p/x^(g*(m+1)+1),x],x,1/(f*x)^(1/g)]] /;
FreeQ[{a,c,d,e,f,p,q},x] && EqQ[n2,2*n] && ILtQ[n,0] && FractionQ[m]

2:  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈(SuperMinus[ℤ])∧ m∉ℚ

Derivation:  Piecewise constant extraction and integration by substitution

Basis: (∂_x)((((f x))^m) ((((x^(-1))))^m))==0

Basis: (((f x))^m) ((((x^(-1))))^m)==(f^(IntPart[m])) (((f x))^(FracPart[m])) ((((x^(-1))))^(FracPart[m]))

Basis: F[x]==-Subst[((F[(x^(-1))] )/(x^2)),x,(1/x)](∂_x)(1/x)

Rule 1.2.3.4.6.2.2: If  (b^2)-4 a c≠0 ∧ n∈(SuperMinus[ℤ])∧ m∉ℚ, then

∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (f^(IntPart[m])) (((f x))^(FracPart[m])) ((((x^(-1))))^(FracPart[m]))∫(((((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p))/((((x^(-1))))^m))dx
  ⟶  -(f^(IntPart[m])) (((f x))^(FracPart[m])) ((((x^(-1))))^(FracPart[m])) Subst[∫(((((d+e (x^(-n))))^q) (((a+b (x^(-n))+c (x^(-2 n))))^p))/(x^(m+2)))dx,x,(1/x)]

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  -f^IntPart[m]*(f*x)^FracPart[m]*(x^(-1))^FracPart[m]*Subst[Int[(d+e*x^(-n))^q*(a+b*x^(-n)+c*x^(-2*n))^p/x^(m+2),x],x,1/x] /;
FreeQ[{a,b,c,d,e,f,m,p,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && ILtQ[n,0] && Not[RationalQ[m]]

Int[(f_.*x_)^m_*(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_.)^p_,x_Symbol] :=
  -f^IntPart[m]*(f*x)^FracPart[m]*(x^(-1))^FracPart[m]*Subst[Int[(d+e*x^(-n))^q*(a+c*x^(-2*n))^p/x^(m+2),x],x,1/x] /;
FreeQ[{a,c,d,e,f,m,p,q},x] && EqQ[n2,2*n] && ILtQ[n,0] && Not[RationalQ[m]]

7.  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈𝔽

1:  ∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈𝔽

Derivation: Integration by substitution

Basis: If  g∈(SuperPlus[ℤ]), then (x^m)F[(x^n)]==g Subst[(x^(g(m+1)-1))F[(x^(g n))],x,(x^(1/g))] (∂_x)(x^(1/g))

Rule 1.2.3.4.7.1: If  (b^2)-4 a c≠0 ∧ n∈𝔽, let g=Denominator[n], then

∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  g Subst[∫(x^(g(m+1)-1)) (((d+e (x^(g n))))^q) (((a+b (x^(g n))+c (x^(2 g n))))^p)dx,x,(x^(1/g))]

Program code:

Int[x_^m_.*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  With[{g=Denominator[n]},
  g*Subst[Int[x^(g*(m+1)-1)*(d+e*x^(g*n))^q*(a+b*x^(g*n)+c*x^(2*g*n))^p,x],x,x^(1/g)]] /;
FreeQ[{a,b,c,d,e,m,p,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && FractionQ[n]

Int[x_^m_.*(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_.)^p_,x_Symbol] :=
  With[{g=Denominator[n]},
  g*Subst[Int[x^(g*(m+1)-1)*(d+e*x^(g*n))^q*(a+c*x^(2*g*n))^p,x],x,x^(1/g)]] /;
FreeQ[{a,c,d,e,m,p,q},x] && EqQ[n2,2*n] && FractionQ[n]

2:  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ n∈𝔽

Derivation: Piecewise constant extraction

Basis: (∂_x)((((f x))^m)/(x^m))==0

Basis: ((((f x))^m)/(x^m))==(((f^(IntPart[m]))(((f x))^(FracPart[m])))/(x^(FracPart[m])))

Rule 1.2.3.4.7.2: If  (b^2)-4 a c≠0 ∧ n∈𝔽, then

∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (((f^(IntPart[m]))(((f x))^(FracPart[m])))/(x^(FracPart[m])))∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(f_*x_)^m_*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  f^IntPart[m]*(f*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(d+e*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,f,m,p,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && FractionQ[n]

Int[(f_*x_)^m_*(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_.)^p_,x_Symbol] :=
  f^IntPart[m]*(f*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(d+e*x^n)^q*(a+c*x^(2*n))^p,x] /;
FreeQ[{a,c,d,e,f,m,p,q},x] && EqQ[n2,2*n] && FractionQ[n]

8.  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ (n/(m+1))∈ℤ

1:  ∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ (n/(m+1))∈ℤ

Derivation: Integration by substitution

Basis: If (n/(m+1))∈ℤ, then (x^m)F[(x^n)]==(1/(m+1))Subst[F[(x^(n/(m+1)))],x,(x^(m+1))](∂_x)(x^(m+1))

Rule 1.2.3.4.8.1: If  (b^2)-4 a c≠0 ∧ (n/(m+1))∈ℤ

∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (1/(m+1))Subst[∫(((d+e (x^(n/(m+1)))))^q)(((a+b (x^(n/(m+1)))+c (x^((2 n)/(m+1)))))^p)dx,x,(x^(m+1))]

Program code:

Int[x_^m_.*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  1/(m+1)*Subst[Int[(d+e*x^Simplify[n/(m+1)])^q*(a+b*x^Simplify[n/(m+1)]+c*x^Simplify[2*n/(m+1)])^p,x],x,x^(m+1)] /;
FreeQ[{a,b,c,d,e,m,n,p,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IntegerQ[Simplify[n/(m+1)]] && Not[IntegerQ[n]]

Int[x_^m_.*(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_.)^p_,x_Symbol] :=
  1/(m+1)*Subst[Int[(d+e*x^Simplify[n/(m+1)])^q*(a+c*x^Simplify[2*n/(m+1)])^p,x],x,x^(m+1)] /;
FreeQ[{a,c,d,e,m,n,p,q},x] && EqQ[n2,2*n] && IntegerQ[Simplify[n/(m+1)]] && Not[IntegerQ[n]]

2:  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ (n/(m+1))∈ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((f x))^m)/(x^m))==0

Basis: ((((f x))^m)/(x^m))==(((f^(IntPart[m]))(((f x))^(FracPart[m])))/(x^(FracPart[m])))

Rule 1.2.3.4.8.2: If  (b^2)-4 a c≠0 ∧ (n/(m+1))∈ℤ, then

∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (((f^(IntPart[m]))(((f x))^(FracPart[m])))/(x^(FracPart[m])))∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(f_*x_)^m_*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_,x_Symbol] :=
  f^IntPart[m]*(f*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(d+e*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,f,m,p,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IntegerQ[Simplify[n/(m+1)]] && Not[IntegerQ[n]]

Int[(f_*x_)^m_*(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_.)^p_,x_Symbol] :=
  f^IntPart[m]*(f*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(d+e*x^n)^q*(a+c*x^(2*n))^p,x] /;
FreeQ[{a,c,d,e,f,m,p,q},x] && EqQ[n2,2*n] && IntegerQ[Simplify[n/(m+1)]] && Not[IntegerQ[n]]

9:  ∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  when  (b^2)-4 a c≠0

Derivation: Algebraic expansion

Basis: If  r=(Sqrt[(b^2)-4a c]), then (1/(a+b z+c (z^2)))==((2c)/(r(b-r+2 c z)))-((2c)/(r(b+r+2 c z)))

Rule 1.2.3.4.9: If  (b^2)-4 a c≠0, then

∫(((((f x))^m) (((d+e (x^n)))^q))/(a+b (x^n)+c (x^(2n))))dx  ⟶  ((2 c)/r)∫(((((f x))^m) (((d+e (x^n)))^q))/(b-r+2 c (x^n)))dx-((2 c)/r)∫(((((f x))^m) (((d+e (x^n)))^q))/(b+r+2 c (x^n)))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_/(a_+b_.*x_^n_+c_.*x_^n2_.),x_Symbol] :=
  With[{r=Rt[b^2-4*a*c,2]},
  2*c/r*Int[(f*x)^m*(d+e*x^n)^q/(b-r+2*c*x^n),x] - 2*c/r*Int[(f*x)^m*(d+e*x^n)^q/(b+r+2*c*x^n),x]] /;
FreeQ[{a,b,c,d,e,f,m,n,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_/(a_+c_.*x_^n2_.),x_Symbol] :=
  With[{r=Rt[-a*c,2]},
  -c/(2*r)*Int[(f*x)^m*(d+e*x^n)^q/(r-c*x^n),x] - c/(2*r)*Int[(f*x)^m*(d+e*x^n)^q/(r+c*x^n),x]] /;
FreeQ[{a,c,d,e,f,m,n,q},x] && EqQ[n2,2*n]

10:  ∫(((f x))^m)(d+e (x^n))(((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ p+1∈(SuperMinus[ℤ])

Derivation: Trinomial recurrence 2b

Rule 1.2.3.4.10: If  (b^2)-4 a c≠0 ∧ p+1∈(SuperMinus[ℤ]), then

∫(((f x))^m) (d+e (x^n))(((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  
-(((((f x))^(m+1)) (((a+b (x^n)+c (x^(2 n))))^(p+1)) (d((b^2)-2 a c)-a b e+(b d-2 a e) c (x^n)))/(a f n(p+1) ((b^2)-4 a c)))+
(1/(a n(p+1)((b^2)-4 a c) ))∫(((f x))^m) (((a+b (x^n)+c (x^(2 n))))^(p+1))·
(d ((b^2) (m+n(p+1)+1)-2 a c (m+2n(p+1)+1))-a b e (m+1)+(m+n(2p+3)+1)(b d-2 a e) c (x^n))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)*(a_+b_.*x_^n_+c_.*x_^n2_)^p_,x_Symbol] :=
  -(f*x)^(m+1)*(a+b*x^n+c*x^(2*n))^(p+1)*(d*(b^2-2*a*c)-a*b*e+(b*d-2*a*e)*c*x^n)/(a*f*n*(p+1)*(b^2-4*a*c)) + 
  1/(a*n*(p+1)*(b^2-4*a*c))*Int[(f*x)^m*(a+b*x^n+c*x^(2*n))^(p+1)*
      Simp[d*(b^2*(m+n*(p+1)+1)-2*a*c*(m+2*n*(p+1)+1))-a*b*e*(m+1)+(m+n*(2*p+3)+1)*(b*d-2*a*e)*c*x^n,x],x] /;
FreeQ[{a,b,c,d,e,f,m,n},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && ILtQ[p+1,0]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)*(a_+c_.*x_^n2_)^p_,x_Symbol] :=
  -(f*x)^(m+1)*(a+c*x^(2*n))^(p+1)*(d+e*x^n)/(2*a*f*n*(p+1)) + 
  1/(2*a*n*(p+1))*Int[(f*x)^m*(a+c*x^(2*n))^(p+1)*Simp[d*(m+2*n*(p+1)+1)+e*(m+n*(2*p+3)+1)*x^n,x],x] /;
FreeQ[{a,c,d,e,f,m,n},x] && EqQ[n2,2*n] && ILtQ[p+1,0]

11:  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ (p∈(SuperPlus[ℤ]) ∨ q∈(SuperPlus[ℤ]))

Derivation: Algebraic expansion

Rule 1.2.3.4.11: If  (b^2)-4 a c≠0 ∧ (p∈(SuperPlus[ℤ]) ∨ q∈(SuperPlus[ℤ])), then

∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ∫ExpandIntegrand[(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m*(d+e*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x],x] /;
FreeQ[{a,b,c,d,e,f,m,n,p,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && (IGtQ[p,0] || IGtQ[q,0])

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m*(d+e*x^n)^q*(a+c*x^(2*n))^p,x],x] /;
FreeQ[{a,c,d,e,f,m,n,p,q},x] && EqQ[n2,2*n] && (IGtQ[p,0] || IGtQ[q,0])

12:  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+c (x^(2 n))))^p)dx  when p∉ℤ ∧ q∈(SuperMinus[ℤ])

Derivation: Algebraic expansion

Basis: If  q∈ℤ, then (((d+e (x^n)))^q)==((((d/((d^2)-(e^2) (x^(2 n))))-((e (x^n))/((d^2)-(e^2) (x^(2 n))))))^(-q))

Note: Resulting integrands are of the form (x^m) (((a+b (x^(2 n))))^p) (((c+d (x^(2 n))))^q) which are integrable in terms of the Appell hypergeometric function .

Rule 1.2.3.4.12: If  p∉ℤ ∧ q∈(SuperMinus[ℤ]), then

∫(((f x))^m) (((d+e (x^n)))^q) (((a+c (x^(2 n))))^p)dx  ⟶  ((((f x))^m)/(x^m)) ∫(x^m) (((a+c (x^(2 n))))^p) ExpandIntegrand[((((d/((d^2)-(e^2) (x^(2 n))))-((e (x^n))/((d^2)-(e^2) (x^(2 n))))))^(-q)),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_*(a_+c_.*x_^n2_)^p_,x_Symbol] :=
  (f*x)^m/x^m*Int[ExpandIntegrand[x^m*(a+c*x^(2*n))^p,(d/(d^2-e^2*x^(2*n))-e*x^n/(d^2-e^2*x^(2*n)))^(-q),x],x] /;
FreeQ[{a,c,d,e,f,m,n,p},x] && EqQ[n2,2*n] && Not[IntegerQ[p]] && ILtQ[q,0]

U:  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Rule 1.2.3.4.X:

∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  Unintegrable[(f*x)^m*(d+e*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,f,m,n,p,q},x] && EqQ[n2,2*n]

Int[(f_.*x_)^m_.*(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  Unintegrable[(f*x)^m*(d+e*x^n)^q*(a+c*x^(2*n))^p,x] /;
FreeQ[{a,c,d,e,f,m,n,p,q},x] && EqQ[n2,2*n]

S:  ∫(u^m)(((d+e (v^n)))^q)(((a+b (v^n)+c (v^(2 n))))^p)dx  when  v==f+g x ∧ u==h v

Derivation: Integration by substitution and piecewise constant extraction

Basis: If  u==h v, then (∂_x)((u^m)/(v^m))==0

Rule 1.2.3.4.S: If  v==f+g x ∧ u==h v, then

∫(u^m)(((d+e (v^n)))^q)(((a+b (v^n)+c (v^(2 n))))^p)dx  ⟶  ((u^m)/(g (v^m)))Subst[∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx,x,v]

Program code:

Int[u_^m_.*(d_+e_.*v_^n_)^q_.*(a_+b_.*v_^n_+c_.*v_^n2_.)^p_.,x_Symbol] :=
  u^m/(Coefficient[v,x,1]*v^m)*Subst[Int[x^m*(d+e*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x],x,v] /;
FreeQ[{a,b,c,d,e,m,n,p,q},x] && EqQ[n2,2*n] && LinearPairQ[u,v,x] && NeQ[v,x]

Int[u_^m_.*(d_+e_.*v_^n_)^q_.*(a_+c_.*v_^n2_.)^p_.,x_Symbol] :=
  u^m/(Coefficient[v,x,1]*v^m)*Subst[Int[x^m*(d+e*x^n)^q*(a+c*x^(2*n))^p,x],x,v] /;
FreeQ[{a,c,d,e,m,n,p},x] && EqQ[n2,2*n] && LinearPairQ[u,v,x] && NeQ[v,x]

Rules for integrands of the form(((f x))^m) (((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)

1.  ∫(x^m) (((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  p∈ℤ ∨ q∈ℤ

1:  ∫(x^m) (((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  q∈ℤ ∧ (n>0 ∨ p∉ℤ)

Derivation: Algebraic simplification

Basis: If  q∈ℤ, then  (((d+e (x^(-n))))^q)==(x^(-n q)) (((e+d (x^n)))^q)

Rule: If  q∈ℤ ∧ (n>0 ∨ p∉ℤ), then

∫(x^m) (((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ∫(x^(m-n q)) (((e+d (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[x_^m_.*(d_+e_.*x_^mn_.)^q_.*(a_.+b_.*x_^n_.+c_.*x_^n2_.)^p_.,x_Symbol] :=
  Int[x^(m-n*q)*(e+d*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && EqQ[n2,2*n] && EqQ[mn,-n] && IntegerQ[q] && (PosQ[n] || Not[IntegerQ[p]])

Int[x_^m_.*(d_+e_.*x_^mn_.)^q_.*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  Int[x^(m+mn*q)*(e+d*x^(-mn))^q*(a+c*x^n2)^p,x] /;
FreeQ[{a,c,d,e,m,mn,p},x] && EqQ[n2,-2*mn] && IntegerQ[q] && (PosQ[n2] || Not[IntegerQ[p]])

2:  ∫(x^m) (((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^(-2 n))))^p)dx  when  p∈ℤ

Derivation: Algebraic simplification

Basis: If  p∈ℤ, then  (((a+b (x^(-n))+c (x^(-2 n))))^p)==(x^(-2 n p)) (((c+b (x^n)+a (x^(2 n))))^p)

Rule: If  p∈ℤ, then

∫(x^m) (((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^(-2 n))))^p)dx  ⟶  ∫(x^(m-2 n p)) (((d+e (x^n)))^q) (((c+b (x^n)+a (x^(2 n))))^p)dx

Program code:

Int[x_^m_.*(d_+e_.*x_^n_.)^q_.*(a_.+b_.*x_^mn_.+c_.*x_^mn2_.)^p_.,x_Symbol] :=
  Int[x^(m-2*n*p)*(d+e*x^n)^q*(c+b*x^n+a*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,m,n,q},x] && EqQ[mn,-n] && EqQ[mn2,2*mn] && IntegerQ[p]

Int[x_^m_.*(d_+e_.*x_^n_.)^q_.*(a_.+c_.*x_^mn2_.)^p_.,x_Symbol] :=
  Int[x^(m-2*n*p)*(d+e*x^n)^q*(c+a*x^(2*n))^p,x] /;
FreeQ[{a,c,d,e,m,n,q},x] && EqQ[mn2,-2*n] && IntegerQ[p]

2.  ∫(x^m) (((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  p∉ℤ ∧ q∉ℤ

1:  ∫(x^m) (((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  p∉ℤ ∧ q∉ℤ ∧ n>0

Derivation: Piecewise constant extraction

Basis: (∂_x)(((x^(n q)) (((d+e (x^(-n))))^q))/(((1+((d (x^n))/e)))^q))==0

Rule: If  p∉ℤ ∧ q∉ℤ ∧ n>0, then

∫(x^m) (((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (((e^(IntPart[q])) (x^(n FracPart[q])) (((d+e (x^(-n))))^(FracPart[q])))/(((1+((d (x^n))/e)))^(FracPart[q]))) ∫(x^(m-n q)) (((1+((d (x^n))/e)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[x_^m_.*(d_+e_.*x_^mn_.)^q_*(a_.+b_.*x_^n_.+c_.*x_^n2_.)^p_.,x_Symbol] :=
  e^IntPart[q]*x^(n*FracPart[q])*(d+e*x^(-n))^FracPart[q]/(1+d*x^n/e)^FracPart[q]*Int[x^(m-n*q)*(1+d*x^n/e)^q*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,m,n,p,q},x] && EqQ[n2,2*n] && EqQ[mn,-n] && Not[IntegerQ[p]] && Not[IntegerQ[q]] && PosQ[n]

Int[x_^m_.*(d_+e_.*x_^mn_.)^q_*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  e^IntPart[q]*x^(-mn*FracPart[q])*(d+e*x^mn)^FracPart[q]/(1+d*x^(-mn)/e)^FracPart[q]*Int[x^(m+mn*q)*(1+d*x^(-mn)/e)^q*(a+c*x^n2)^p,x] /;
FreeQ[{a,c,d,e,m,mn,p,q},x] && EqQ[n2,-2*mn] && Not[IntegerQ[p]] && Not[IntegerQ[q]] && PosQ[n2]

x:  ∫(x^m) (((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  p∉ℤ ∧ q∉ℤ ∧ n>0

Derivation: Piecewise constant extraction

Basis: (∂_x)(((x^(n q)) (((d+e (x^(-n))))^q))/(((e+d (x^n)))^q))==0

Rule: If  p∉ℤ ∧ q∉ℤ ∧ n>0, then

∫(x^m) (((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (((x^(n FracPart[q])) (((d+e (x^(-n))))^(FracPart[q])))/(((e+d (x^n)))^(FracPart[q]))) ∫(x^(m-n q)) (((e+d (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

(* Int[x_^m_.*(d_+e_.*x_^mn_.)^q_*(a_.+b_.*x_^n_.+c_.*x_^n2_.)^p_.,x_Symbol] :=
  x^(n*FracPart[q])*(d+e*x^(-n))^FracPart[q]/(e+d*x^n)^FracPart[q]*Int[x^(m-n*q)*(e+d*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,m,n,p,q},x] && EqQ[n2,2*n] && EqQ[mn,-n] && Not[IntegerQ[p]] && Not[IntegerQ[q]] && PosQ[n] *)

(* Int[x_^m_.*(d_+e_.*x_^mn_.)^q_*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  x^(-mn*FracPart[q])*(d+e*x^mn)^FracPart[q]/(e+d*x^(-mn))^FracPart[q]*Int[x^(m+mn*q)*(e+d*x^(-mn))^q*(a+c*x^n2)^p,x] /;
FreeQ[{a,c,d,e,m,mn,p,q},x] && EqQ[n2,-2*mn] && Not[IntegerQ[p]] && Not[IntegerQ[q]] && PosQ[n2] *)

2:  ∫(x^m) (((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^(-2 n))))^p)dx  when  p∉ℤ ∧ q∉ℤ ∧ n>0

Derivation: Piecewise constant extraction

Basis: (∂_x)(((x^(2 n p)) (((a+b (x^(-n))+c (x^(-2 n))))^p))/(((c+b (x^n)+a (x^(2 n))))^p))==0

Rule: If  p∉ℤ ∧ q∉ℤ ∧ n>0, then

∫(x^m) (((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^(-2 n))))^p)dx  ⟶  (((x^(2 n FracPart[p])) (((a+b (x^(-n))+c (x^(-2 n))))^(FracPart[p])))/(((c+b (x^n)+a (x^(2 n))))^(FracPart[p]))) ∫(x^(m-2 n p)) (((d+e (x^n)))^q) (((c+b (x^n)+a (x^(2 n))))^p)dx

Program code:

Int[x_^m_.*(d_+e_.*x_^n_.)^q_.*(a_.+b_.*x_^mn_.+c_.*x_^mn2_.)^p_,x_Symbol] :=
  x^(2*n*FracPart[p])*(a+b*x^(-n)+c*x^(-2*n))^FracPart[p]/(c+b*x^n+a*x^(2*n))^FracPart[p]*
    Int[x^(m-2*n*p)*(d+e*x^n)^q*(c+b*x^n+a*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,m,n,p,q},x] && EqQ[mn,-n] && EqQ[mn2,2*mn] && Not[IntegerQ[p]] && Not[IntegerQ[q]] && PosQ[n]

Int[x_^m_.*(d_+e_.*x_^n_.)^q_.*(a_.+c_.*x_^mn2_.)^p_,x_Symbol] :=
  x^(2*n*FracPart[p])*(a+c*x^(-2*n))^FracPart[p]/(c+a*x^(2*n))^FracPart[p]*
    Int[x^(m-2*n*p)*(d+e*x^n)^q*(c+a*x^(2*n))^p,x] /;
FreeQ[{a,c,d,e,m,n,p,q},x] && EqQ[mn2,-2*n] && Not[IntegerQ[p]] && Not[IntegerQ[q]] && PosQ[n]

3:  ∫(((f x))^m) (((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Derivation: Piecewise constant extraction

Basis: (∂_x)((((f x))^m)/(x^m))==0

Rule:

∫(((f x))^m) (((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (((f^(IntPart[m]))(((f x))^(FracPart[m])))/(x^(FracPart[m])))∫(x^m) (((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(f_*x_)^m_*(d_+e_.*x_^mn_.)^q_.*(a_.+b_.*x_^n_.+c_.*x_^n2_.)^p_.,x_Symbol] :=
  f^IntPart[m]*(f*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(d+e*x^mn)^q*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,f,m,n,p,q},x] && EqQ[n2,2*n] && EqQ[mn,-n]

Int[(f_*x_)^m_*(d_+e_.*x_^mn_.)^q_.*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  f^IntPart[m]*(f*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(d+e*x^mn)^q*(a+c*x^n2)^p,x] /;
FreeQ[{a,c,d,e,f,m,mn,p,q},x] && EqQ[n2,-2*mn]

Rules for integrands of the form(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^n)))^p)

1.  ∫(x^m) (((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^n)))^p)dx

1:  ∫(x^m) (((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^n)))^p)dx  when  p∈ℤ

Derivation: Algebraic normalization

Basis: a+b (x^(-n))+c (x^n)==(x^(-n)) (b+a (x^n)+c (x^(2 n)))

Rule 1.2.3.4.13.1.1: If  p∈ℤ, then

∫(x^m) (((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^n)))^p)dx  ⟶  ∫(x^(m-n p)) (((d+e (x^n)))^q) (((b+a (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[x_^m_.*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^mn_+c_.*x_^n_.)^p_.,x_Symbol] :=
  Int[x^(m-n*p)*(d+e*x^n)^q*(b+a*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,m,n,q},x] && EqQ[mn,-n] && IntegerQ[p]

2:  ∫(x^m) (((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^n)))^p)dx  when  p∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)(((x^(n p)) (((a+b (x^(-n))+c (x^n)))^p))/(((b+a (x^n)+c (x^(2 n))))^p))==0

Basis: (((x^(n p)) (((a+b (x^(-n))+c (x^n)))^p))/(((b+a (x^n)+c (x^(2 n))))^p))==(((x^(n FracPart[p])) (((a+b (x^(-n))+c (x^n)))^(FracPart[p])))/(((b+a (x^n)+c (x^(2 n))))^(FracPart[p])))

Rule 1.2.3.4.13.1.2: If  p∉ℤ, then

∫(x^m) (((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^n)))^p)dx  ⟶  (((x^(n FracPart[p])) (((a+b (x^(-n))+c (x^n)))^(FracPart[p])))/(((b+a (x^n)+c (x^(2 n))))^(FracPart[p])))∫(x^(m-n p)) (((d+e (x^n)))^q) (((b+a (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[x_^m_.*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^mn_+c_.*x_^n_.)^p_.,x_Symbol] :=
  x^(n*FracPart[p])*(a+b/x^n+c*x^n)^FracPart[p]/(b+a*x^n+c*x^(2*n))^FracPart[p]*
    Int[x^(m-n*p)*(d+e*x^n)^q*(b+a*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,m,n,p,q},x] && EqQ[mn,-n] && Not[IntegerQ[p]]

2:  ∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^n)))^p)dx

Derivation: Piecewise constant extraction

Basis: (∂_x)((((f x))^m)/(x^m))==0

Basis: ((((f x))^m)/(x^m))==(((f^(IntPart[m]))(((f x))^(FracPart[m])))/(x^(FracPart[m])))

Rule 1.2.3.4.13.2:

∫(((f x))^m) (((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^n)))^p)dx  ⟶  (((f^(IntPart[m]))(((f x))^(FracPart[m])))/(x^(FracPart[m]))) ∫(x^m) (((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^n)))^p)dx

Program code:

Int[(f_*x_)^m_.*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^mn_+c_.*x_^n_.)^p_.,x_Symbol] :=
  f^IntPart[m]*(f*x)^FracPart[m]/x^FracPart[m]*Int[x^m*(d+e*x^n)^q*(a+b*x^(-n)+c*x^n)^p,x] /;
FreeQ[{a,b,c,d,e,f,m,n,p,q},x] && EqQ[mn,-n]

Rules for integrands of the form(((f x))^m) ((((Subscript[d, 1])+(Subscript[e, 1]) (x^(n/2))))^q) ((((Subscript[d, 2])+(Subscript[e, 2]) (x^(n/2))))^q) (((a+b (x^n)+c (x^(2 n))))^p)

1.  ∫(((f x))^m) ((((Subscript[d, 1])+(Subscript[e, 1]) (x^(n/2))))^q) ((((Subscript[d, 2])+(Subscript[e, 2]) (x^(n/2))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (Subscript[d, 2]) (Subscript[e, 1])+(Subscript[d, 1]) (Subscript[e, 2])==0

1:  ∫(((f x))^m) ((((Subscript[d, 1])+(Subscript[e, 1]) (x^(n/2))))^q) ((((Subscript[d, 2])+(Subscript[e, 2]) (x^(n/2))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (Subscript[d, 2]) (Subscript[e, 1])+(Subscript[d, 1]) (Subscript[e, 2])==0 ∧ (q∈ℤ ∨ (Subscript[d, 1])>0 ∧ (Subscript[d, 2])>0)

Derivation: Algebraic simplification

Basis: If  (Subscript[d, 2]) (Subscript[e, 1])+(Subscript[d, 1]) (Subscript[e, 2])==0 ∧ (q∈ℤ ∨ (Subscript[d, 1])>0 ∧ (Subscript[d, 2])>0), then ((((Subscript[d, 1])+(Subscript[e, 1]) (x^(n/2))))^q) ((((Subscript[d, 2])+(Subscript[e, 2]) (x^(n/2))))^q)==((((Subscript[d, 1]) (Subscript[d, 2])+(Subscript[e, 1]) (Subscript[e, 2]) (x^n)))^q)

Rule: If  (Subscript[d, 2]) (Subscript[e, 1])+(Subscript[d, 1]) (Subscript[e, 2])==0 ∧ (q∈ℤ ∨ (Subscript[d, 1])>0 ∧ (Subscript[d, 2])>0), then

∫(((f x))^m) ((((Subscript[d, 1])+(Subscript[e, 1]) (x^(n/2))))^q) ((((Subscript[d, 2])+(Subscript[e, 2]) (x^(n/2))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ∫(((f x))^m) ((((Subscript[d, 1]) (Subscript[d, 2])+(Subscript[e, 1]) (Subscript[e, 2]) (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(f_.*x_)^m_.*(d1_+e1_.*x_^non2_.)^q_.*(d2_+e2_.*x_^non2_.)^q_.*(a_.+b_.*x_^n_+c_.*x_^n2_)^p_.,x_Symbol] :=
  Int[(f*x)^m*(d1*d2+e1*e2*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,n,p,q},x] && EqQ[n2,2*n] && EqQ[non2,n/2] && EqQ[d2*e1+d1*e2,0] && (IntegerQ[q] || GtQ[d1,0] && GtQ[d2,0])

2:  ∫(((f x))^m) ((((Subscript[d, 1])+(Subscript[e, 1]) (x^(n/2))))^q) ((((Subscript[d, 2])+(Subscript[e, 2]) (x^(n/2))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (Subscript[d, 2]) (Subscript[e, 1])+(Subscript[d, 1]) (Subscript[e, 2])==0

Derivation: Piecewise constant extraction

Basis: If  (Subscript[d, 2]) (Subscript[e, 1])+(Subscript[d, 1]) (Subscript[e, 2])==0, then (∂_x)((((((Subscript[d, 1])+(Subscript[e, 1]) (x^(n/2))))^q) ((((Subscript[d, 2])+(Subscript[e, 2]) (x^(n/2))))^q))/((((Subscript[d, 1]) (Subscript[d, 2])+(Subscript[e, 1]) (Subscript[e, 2]) (x^n)))^q))==0

Rule: If  (Subscript[d, 2]) (Subscript[e, 1])+(Subscript[d, 1]) (Subscript[e, 2])==0, then

∫(((f x))^m) ((((Subscript[d, 1])+(Subscript[e, 1]) (x^(n/2))))^q) ((((Subscript[d, 2])+(Subscript[e, 2]) (x^(n/2))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  
((((((Subscript[d, 1])+(Subscript[e, 1]) (x^(n/2))))^(FracPart[q])) ((((Subscript[d, 2])+(Subscript[e, 2]) (x^(n/2))))^(FracPart[q])))/((((Subscript[d, 1]) (Subscript[d, 2])+(Subscript[e, 1]) (Subscript[e, 2]) (x^n)))^(FracPart[q])))∫(((f x))^m) ((((Subscript[d, 1]) (Subscript[d, 2])+(Subscript[e, 1]) (Subscript[e, 2]) (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(f_.*x_)^m_.*(d1_+e1_.*x_^non2_.)^q_.*(d2_+e2_.*x_^non2_.)^q_.*(a_.+b_.*x_^n_+c_.*x_^n2_)^p_.,x_Symbol] :=
  (d1+e1*x^(n/2))^FracPart[q]*(d2+e2*x^(n/2))^FracPart[q]/(d1*d2+e1*e2*x^n)^FracPart[q]*
    Int[(f*x)^m*(d1*d2+e1*e2*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,f,n,p,q},x] && EqQ[n2,2*n] && EqQ[non2,n/2] && EqQ[d2*e1+d1*e2,0]